CODEWITHSUNDEEP
excel
Rob
Rob

Reputation: 6380

Add " to the start and " to the end of each cell data

I have a fairly large Excel csv file that I need to add " and " to the start and end of each cell.

The cells contain mixed text whether it's

etc, all of which I need to add quotes to the start and end of each cell.

How can I do this?

Upvotes: 1

Views: 4429

Answers (2)

brettdj
brettdj

Reputation: 55692

I have adapted this code from Excel show leading zero in formula bar

It uses variant arrays for speed efficiency, updating only the UsedRange portion of the spreadsheet

  • press Alt & F11 together to go the VBE
  • Insert Module
  • copy and paste the code below
  • press Alt & F11 together to go back to Excel
  • run the macro from the Developer tab

It can be adapted to ignore blanks cells if you so wish - let me know

Sub AddStrings()
Dim rng1 As Range
Dim rngArea As Range
Dim strRep1 As String
Dim strRep2 As String
Dim lngRow As Long
Dim lngCol As Long
Dim lngCalc As Long
Dim X()


strRep1 = """"
strRep2 = """"

ActiveSheet.UsedRange
Set rng1 = ActiveSheet.UsedRange

'Speed up the code by turning off screenupdating and setting calculation to manual
'Disable any code events that may occur when writing to cells
With Application
    lngCalc = .Calculation
    .ScreenUpdating = False
    .Calculation = xlCalculationManual
    .EnableEvents = False
End With

'Test each area in the user selected range

'Non contiguous range areas are common when using SpecialCells to define specific cell types to work on
For Each rngArea In rng1.Areas
    'The most common outcome is used for the True outcome to optimise code speed
    If rngArea.Cells.Count > 1 Then
        'If there is more than once cell then set the variant array to the dimensions of the range area
        'Using Value2 provides a useful speed improvement over Value. On my testing it was 2% on blank cells, up to 10% on non-blanks
        X = rngArea.Value2
        For lngRow = 1 To rngArea.Rows.Count
            For lngCol = 1 To rngArea.Columns.Count
                'replace the leading zeroes
                X(lngRow, lngCol) = strRep1 & X(lngRow, lngCol) & strRep2
            Next lngCol
        Next lngRow
        'Dump the updated array sans leading zeroes back over the initial range
        rngArea.Value2 = X
    Else
        'caters for a single cell range area. No variant array required
        rngArea.Value = strRep1 & rngArea.Value2 & strRep2
    End If
Next rngArea

'cleanup the Application settings
With Application
    .ScreenUpdating = True
    .Calculation = lngCalc
    .EnableEvents = True
End With

End Sub

Upvotes: 1

fanlix
fanlix

Reputation: 1378

by hand:

  • change 1st cell value to =""""&A1&""""
  • drag this cell format to full page

or by vb macro

Upvotes: 2

Related Questions