parse a svg xml with asp

Question

I need to get an attribute from svg file on classic asp. But my code don't work. Any idea?

id attribute from font tag.

asp function

function getFontId(url)
Set objXml = Server.CreateObject("MSXML2.DomDocument.6.0")
'objXml.async = False
objXml.LoadXML(url)

For Each oNode In objXml.SelectNodes("svg/defs/font")
  sKey = oNode.GetAttribute("id")
 ' sValue = oNode.Text
  getXML=sKey
Next

Set objXml= Nothing
end function

svg code:

Kul-Tigin · Accepted Answer

You can parse specifying svg selection namespace.
Plus, the parameter name is url, this make sense if it's a url? Because loadXML loads only from a string containing xml. You should use Load with setting ServerHTTPRequest property to True if url is remote. Check out validateOnParse and resolveExternals. Here's an example:

Function getFontId(url)
    With Server.CreateObject("MSXML2.DomDocument.6.0")
        .async = False
        .validateOnParse = False 'parse only for well-formed xml, no more
        .resolveExternals = False
        .setProperty "ServerHTTPRequest", True
        .setProperty "ProhibitDTD", False ' it's true by default in 6.0
        If .Load(url) Then
            .setProperty "SelectionNamespaces", "xmlns:svg='http://www.w3.org/2000/svg'"
            Dim domAttrId
            Set domAttrId = .selectSingleNode("//svg:defs/svg:font/@id")
            If domAttrId Is Nothing Then 
                'node nor attribute not exists
            Else
                getFontId = domAttrId.Value
            End If
        Else
            With .parseError
                Err.Raise .errorCode, .srcText, .reason
            End With
        End If
    End With
End Function

parse a svg xml with asp

Answers (2)

Related Questions