CODEWITHSUNDEEP
perlmerge
Ashish Sharma
Ashish Sharma

Reputation: 1635

merging two files using perl keeping the copy of original file in other file

I have to files like A.ini and B.ini ,I want to merge both the files in A.ini

examples of files:
A.ini::

a=123
b=xyx
c=434

B.ini contains:
a=abc
m=shank
n=paul

my output in files A.ini should be like

a=123abc
b=xyx
c=434
m=shank
n=paul

I want to this merging to be done in perl language and I want to keep the copy of old A.ini file at some other place to use old copy

Upvotes: 0

Views: 1077

Answers (3)

Borodin
Borodin

Reputation: 126722

The two files to be merged can be read in a single pass and don't need to be treated as separate source files. That allows the use of <> to read all files passed as parameters on the command line.

Keeping a backup copy of A.ini is simply a matter of renaming it before writing the merged data to a new file of the same name.

This program appears to do what you need.

use strict;
use warnings;

my $file_a = $ARGV[0];

my (@keys, %values);

while (<>) {
  if (/\A\s*(.+?)\s*=\s*(.+?)\s*\z/) {
    push @keys, $1 unless exists $values{$1};
    $values{$1} .= $2;
  }
}

rename $file_a, "$file_a.bak" or die qq(Unable to rename "$file_a": $!);
open my $fh, '>', $file_a or die qq(Unable to open "$file_a" for output: $!);
printf $fh "%s=%s\n", $_, $values{$_} for @keys;

output (in A.ini)

a=123abc
b=xyx
c=434
m=shank
n=paul

Upvotes: 0

yazu
yazu

Reputation: 4650

A command line variant:

perl -lne '
($a, $b) = split /=/;
$v{$a} = $v{$a} ? $v{$a} . $b : $_;
END {
  print $v{$_} for sort keys %v
}' A.ini B.ini >NEW.ini

Upvotes: 1

Toto
Toto

Reputation: 91385

How about:

#!/usr/bin/perl
use strict;
use warnings;

my %out;
my $file = 'path/to/A.ini';
open my $fh, '<', $file or die "unable to open '$file' for reading: $!";
while(<$fh>) {
    chomp;
    my ($key, $val) = split /=/;
    $out{$key} = $val;
}
close $fh;

$file = 'path/to/B.ini';
open my $fh, '<', $file or die "unable to open '$file' for reading: $!";
while(<$fh>) {
    chomp;
    my ($key, $val) = split /=/;
    if (exists $out{$key}) {
        $out{$key} .= $val;
    } else {
        $out{$key} = $val;
    }
}
close $fh;

$file = 'path/to/A.ini';
open my $fh, '>', $file or die "unable to open '$file' for writing: $!";
foreach(keys %out) {
    print $fh $_,'=',$out{$_},"\n";
}
close $fh;

Upvotes: 0

Related Questions