CODEWITHSUNDEEP
debuggingvb6console
CodeBlue
CodeBlue

Reputation: 15409

How to write to a debug console in VB6?

I am new to VB. I want to test some old VB code, but I need the ability to print to the console to be able to test certain values that are set in the code. How to print to the console from VB?

Upvotes: 16

Views: 32407

Answers (4)

MarkJ
MarkJ

Reputation: 30408

Use OutputDebugString and view the messages with the excellent free DebugView. Debug executables or from the IDE. More information and reusable code from Karl Peterson here

Upvotes: 4

Bob77
Bob77

Reputation: 13267

This isn't expected to be the accepted answer because Debug.Print is the way to go for IDE testing.

However just to show how to use the standard I/O streams easily in VB6:

Option Explicit
'
'Reference to Microsoft Scripting Runtime.
'

Public SIn As Scripting.TextStream
Public SOut As Scripting.TextStream

'--- Only required for testing in IDE or Windows Subsystem ===
Private Declare Function AllocConsole Lib "kernel32" () As Long
Private Declare Function GetConsoleTitle Lib "kernel32" _
    Alias "GetConsoleTitleA" ( _
    ByVal lpConsoleTitle As String, _
    ByVal nSize As Long) As Long
Private Declare Function FreeConsole Lib "kernel32" () As Long

Private Allocated As Boolean

Private Sub Setup()
    Dim Title As String

    Title = Space$(260)
    If GetConsoleTitle(Title, 260) = 0 Then
        AllocConsole
        Allocated = True
    End If
End Sub

Private Sub TearDown()
    If Allocated Then
        SOut.Write "Press enter to continue..."
        SIn.ReadLine
        FreeConsole
    End If
End Sub
'--- End testing ---------------------------------------------

Private Sub Main()
    Setup 'Omit for Console Subsystem.

    With New Scripting.FileSystemObject
        Set SIn = .GetStandardStream(StdIn)
        Set SOut = .GetStandardStream(StdOut)
    End With

    SOut.WriteLine "Any output you want"
    SOut.WriteLine "Goes here"

    TearDown 'Omit for Console Subsystem.
End Sub

Note that very little of the code there is required for an actual Console program in VB6. The bulk of it is about allocating a Console window when the program is not running in the Console Subsystem.

Upvotes: 12

Binary Worrier
Binary Worrier

Reputation: 51739

This isn't something that Vb6 can easily do (I'm sure it can be done, but you'd be calling native Win32 APIs, and isn't worth the pain if you're just using it for debugging)

Your best bet (IMHO) is to write those values to a log file.

Upvotes: 0

gbianchi
gbianchi

Reputation: 2138

Use debug.print. But there is no console on a VB6 application, that will print to the debug window.

Upvotes: 26

Related Questions