CODEWITHSUNDEEP
vbaoutlook
tonyyeb
tonyyeb

Reputation: 719

Add contacts to Outlook Distribution List

I have 1000+ contacts each with a selection of common job titles. I'd like to programmatically add each job title group (e.g. all the contacts with the job title 'Managing Director') into a Distribution List (e.g. 'Managing Directors').

Upvotes: 3

Views: 6979

Answers (1)

Siddharth Rout
Siddharth Rout

Reputation: 149277

Ok here is an example for only the default Contacts folder. Similarly, you have to go to every folder where a DL might exist, starting with the default Contacts folder to check if the Dist List exists before creating it.

TRIED AND TESTED (IN OUTLOOK VBA)

Option Explicit

Sub GetJobList()
    Dim olApp As Outlook.Application
    Dim olNmspc As Outlook.NameSpace
    Dim olAdLst As Outlook.AddressList
    Dim olAdLstEntry As Outlook.AddressEntry
    Dim olDLst As Outlook.DistListItem, olDLstItem As Outlook.DistListItem
    Dim olMailItem As Outlook.MailItem
    Dim olRecipients As Outlook.Recipients

    Dim jobT() As String, JobTitle As String
    Dim i As Long

    Set olApp = New Outlook.Application
    Set olNmspc = olApp.GetNamespace("MAPI")

    i = 0

    '~~> Loop through the address entries
    For Each olAdLst In olNmspc.AddressLists
        Select Case UCase(olAdLst.Name)
            Case "CONTACTS"
                '~~> Get the Job Title
                For Each olAdLstEntry In olAdLst.AddressEntries
                    On Error Resume Next
                    JobTitle = Trim(olAdLstEntry.GetContact.JobTitle)
                    On Error GoTo 0

                    If JobTitle <> "" Then
                        ReDim Preserve jobT(i)
                        jobT(i) = olAdLstEntry.GetContact.JobTitle
                        i = i + 1
                    End If
                Next
        End Select
    Next

    '~~> Loop through the job title to create the distribution lists
    For i = LBound(jobT) To UBound(jobT)
        '~~> Check if the DL List exists
        On Error Resume Next
        Set olDLst = olNmspc.GetDefaultFolder(olFolderContacts).Items(jobT(i))
        On Error GoTo 0

        '~~> If not then create it
        If olDLst Is Nothing Then
            Set olDLst = olApp.CreateItem(7)
            olDLst.DLName = jobT(i)
            olDLst.Save
        End If
    Next i

    '~~> Loop through the address entries to add contact to relevant Distribution list
    For Each olAdLst In olNmspc.AddressLists
        Select Case UCase(olAdLst.Name)
            Case "CONTACTS"
                '~~> Get the Job Title
                For Each olAdLstEntry In olAdLst.AddressEntries
                    On Error Resume Next
                    JobTitle = Trim(olAdLstEntry.GetContact.JobTitle)
                    On Error GoTo 0

                    If JobTitle <> "" Then
                        On Error Resume Next
                        Set olDLst = olNmspc.GetDefaultFolder(olFolderContacts).Items(JobTitle)
                        On Error GoTo 0

                        '~~> Create a mail item
                        Set olMailItem = olApp.CreateItem(0)
                        Set olRecipients = olMailItem.Recipients
                        olRecipients.Add olAdLstEntry.GetContact.Email1Address

                        '~~> Add to distribution list
                        With olDLst
                            .AddMembers olRecipients
                            .Close olSave
                        End With

                        Set olMailItem = Nothing
                        Set olRecipients = Nothing
                    End If
                Next
        End Select
    Next

    Set olNmspc = Nothing
    Set olApp = Nothing
    Set olDLst = Nothing

End Sub

Upvotes: 6

Related Questions