CODEWITHSUNDEEP
gnuplot
user82238
user82238

Reputation:

Can the string for "set title" be obtained from a file?

I'm using Gnuplot with scripts and data files.

In my script there is a command;

set title "blah title here"

Is it possible to have that string taken from a data file? e.g. such that I can use a single script with many data files, because the data file will contain the title for the plot.

Upvotes: 3

Views: 6513

Answers (3)

theozh
theozh

Reputation: 25714

Even if this is rather late and the OP's account doesn't exist anymore, I need to add an answer, because it is simply not true that you cannot extract a title from a datafile with gnuplot only.

You can run stats (check help stats) without actually being interested in statistics but just for extracting the title. You limit the data to the line of interest via every (check help every). This works for gnuplot 4.6.0 (March 2012).

For gnuplot>=4.6.0 you can set a character as datafile separator (check help datafile separator). Take a character which doesn't appear in the line with the title. For gnuplot>=4.6.0 you can set datafile separator "\t" or for gnuplot>=5.0.0 you can also set datafile separator "\n".

Data: SO10968529.dat

# This is a commented line
"Line2: This is a uncommented line in double quotes"
"Line3: my Title"

Line5: This is a title without quotation marks
"Line6: Another title"
# x   y
  1   5.0
  2   3.0
  3   4.0
  4   2.0
# end of data

Script:

### read title from datafile
reset

FILE = "SO10968529.dat"

set multiplot layout 1,2

    set datafile separator "\t"
    stats FILE u (myTitle=strcol(1),0) every ::0:0:0:0 nooutput
    set datafile separator whitespace
    set title myTitle
    plot FILE u 1:2 w lp pt 7 lc rgb "red"

    set datafile separator "\t"
    stats FILE u (myTitle=strcol(1),0) every ::0:1:0:1 nooutput
    set datafile separator whitespace
    set title myTitle
    plot FILE u 1:2 w lp pt 7 lc rgb "blue"

unset multiplot
### end of script

Result:

enter image description here

Upvotes: 1

andyras
andyras

Reputation: 15910

I'm not sure if this would be easy to do in pure gnuplot, but here is a solution using a wrapper bash script. You would use the script by calling plotscript.sh data.dat at the command line.

#!/bin/bash

my_title=$(head -n 1 $1 | sed 's/^# \(.*\)/\1/')

echo "set terminal postscript enhanced color
set output 'plot.eps'

set title '$my_title'
plot '$1' u 1:2" | gnuplot

To make the script usable put the code in a textfile and run chmod +x on it. If you tell me what format the title is in I can try to tailor the script to match that. This script assumes that the title is the first line of the data file in this type of format:

# mytitle

1 4
2 5
3 2

Upvotes: 5

mgilson
mgilson

Reputation: 309841

you can use backtic substitution...e.g.

set title "`head -1 datafile.dat`"

However, that doesn't quite get what you want since the backtic substitution is done prior to string operations (You can't specify the datafile name as a string). However, Macros are expanded prior to backtic substitutions.

My test datafile looked like:

"this is the title"
10 20
20 30
30 40

And my test script looked like:

DATAFILE="datafile.dat"
set macro
TI='`head -1 '.DATAFILE.'`'  #macro: Single quotes are important here to prevent expansion of backtics.
set title @TI
plot DATAFILE u 1:2 title columnhead(1)

Note that if your title isn't enclosed in double quotes in the datafile, you'll need to add them so that the resulting set title command is valid. (You can either add them to the macro, or to the datafile)

Upvotes: 2

Related Questions