CODEWITHSUNDEEP
xmlxslt
Vini
Vini

Reputation: 8419

XSLT: <xsl:strip-space> does not work

I have a servlet filter in my application that intercepts all the incoming requests and tries to strip the whitespaces from the incoming XML and write the resulting 'clean' XML to the response. I am using XSLT to achieve this. Please see the XSLT below:

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">

<xsl:output method="xml" omit-xml-declaration="no" indent="yes"/>
<xsl:strip-space elements="*"/>

<xsl:template match="@*|node()">
<xsl:copy>
    <xsl:apply-templates select="@*|node()"/>
</xsl:copy>
</xsl:template>
</xsl:stylesheet>

However, this is not working as expected. The resulting XML is the same as the original XML (despite of using the <xsl:strip-space elements="*"/> in the stylesheet.

Please help me getting this right.

Regards,
- Ashish

Upvotes: 7

Views: 19526

Answers (3)

Pavel Minaev
Pavel Minaev

Reputation: 101615

Assuming that by "trim" you mean "remove all whitespace immediately after opening and before closing tags", then the following additional template rules should do the trick:

<xsl:variable name="whitespace">&#x20;&#x9;&#xD;&#xA;</xsl:variable>

<!-- Trim all whitespace at end of string -->
<xsl:template name="trim-end">
   <xsl:param name="text"/>
   <xsl:variable name="last-char" select="substring($text, string-length($text), 1)" />
   <xsl:choose>
     <xsl:when test="contains($whitespace, $last-char)">
       <xsl:call-template name="trim-end">
         <xsl:with-param name="text" select="substring($text, 1, string-length($text) - 1)" />
       </xsl:call-template>
     </xsl:when>
     <xsl:otherwise>
       <xsl:value-of select="$text" />
     </xsl:otherwise>
   </xsl:choose>
</xsl:template>

<xsl:template match="text()">
  <xsl:call-template name="trim-start">
    <xsl:with-param name="text">
      <xsl:call-template name="trim-end">
        <xsl:with-param name="text" select="." />
      </xsl:call-template>
    </xsl:with-param>
  </xsl:call-template>
</xsl:template>

Upvotes: 3

alanstroop
alanstroop

Reputation:

Using the xslt from the original question, a <xsl:template match="text()"><xsl:value-of select="normalize-space(.)"/></xsl:template> should do the trick.

Upvotes: 17

Pavel Minaev
Pavel Minaev

Reputation: 101615

It is not clear what you intend to get as an output, and what you expect from xsl:strip-whitespace in the first place. But one thing to note is that it doesn't strip all whitespace, but only that which is deemed insignificant under the "usual" rules. In particular, from XSLT 1.0 spec:

A text node is never stripped unless it contains only whitespace characters.

So, for example, this:

<foo>
  <bar>   </bar>
</foo>

will be stripped down to:

<foo><bar/></foo>

because it had 3 whitespace-only text nodes (after <foo> and before <bar>, between <bar> and </bar>, and after </bar> and before </foo>).

Note also that because you have <xsl:output indent="yes"> in your stylesheet, it will end up being transformed to:

<foo>
   <bar/>
<foo>

in the output.

On the other hand, this:

<foo>
   text1
   <bar>  text2  </bar>
   text3
</foo>

Will not be stripped at all, because all text nodes it contains are not purely whitespace nodes.

Upvotes: 20

Related Questions