CODEWITHSUNDEEP
regextclsubstitution
feronjb
feronjb

Reputation: 355

TCL, regexp function and parameter substitution

I have the following code where I'm trying to match data on a single line into different variables via the regexp function. The number of data (on the input line) and then of variable names in regexp function can vary, that's why I use $varLine (which is previously processed in my real code). 

set in_stim "13 1 1 0 1 0 0 0 2 03"
set regex {^(\d+)\s([01])\s([01])\s([01])\s([01])\s([01])\s([01])\s([01])\s(\d+)\s(\d+)}
set varLine "sig1 sig2 sig3 sig4 sig5 sig6 sig7 sig8 sig8"
regexp $regex $in_stim whole sig0 $varLine
puts "sig0: $sig0"
puts $sig1

When I am executing it, I get the following error ($sig0 is correctly displayed): 

    sig0: 13

    can't read "sig1": no such variable
    while executing
"puts $sig1"

If I manually substitute $varLine into the regexp line, the error disappears:

set in_stim "13 1 1 0 1 0 0 0 2 03"
set regex {^(\d+)\s([01])\s([01])\s([01])\s([01])\s([01])\s([01])\s([01])\s(\d+)\s(\d+)}
regexp $regex $in_stim whole sig0 sig1 sig2 sig3 sig4 sig5 sig6 sig7 sig8 sig8
puts $sig0
puts $sig1

I get the following correct output:

13
1

Does anyone see mistakes in my code or could help? Thanks!

Upvotes: 0

Views: 1108

Answers (2)

Donal Fellows
Donal Fellows

Reputation: 137697

The issue is that the regexp command doesn't take a list of variables to store submatches into as one argument, but rather as many arguments.

The simplest method of working around this is to expand the variable list:

regexp $regex $in_stim whole sig0 {*}$varLine

Upvotes: 2

kostix
kostix

Reputation: 55513

When you do

set varLine "sig1 sig2 sig3 sig4 sig5 sig6 sig7 sig8 sig8"
regexp $regex $in_stim whole sig0 $varLine

the Tcl parser passes the regexp command exactly five arguments, with the fifth argument being the contents of the variable "varLine" which is then treated by the regexp command as a single word. A single word obviously denotes a single variable (with somewhat complex name in your case, as it happens).

To do what you need, you have to resort to dynamic scripting which can be done in two ways:

  1. "Classic" approach using eval:

    eval [concat [list regexp $regex $in_stim whole sig0] $varLine]

  2. Using the {*} syntactic sugar from Tcl 8.5 onwards:

    regexp $regex $in_stim whole sig0 {*}$varLine

The classic approach first constructs a list of words by concatenating two lists: the "static" part of the command and then the list of variables to pass to it. Then the constructed list is evaluated as a command. You can read more on this in this classic book.

In the new-style approach, the {*} thingy is used to expand the contents of $varLine into an "in-place" list — refer to the 5th rule here.

Upvotes: 2

Related Questions