vb.net queue that runs every 10 seconds

Question

i have a queue that runs every 10 seconds:

Private Sub Form1Load(ByVal sender As Object, ByVal e As EventArgs) Handles MyBase.Load

        Dim t As New Timers.Timer(10000)
        AddHandler t.Elapsed, New ElapsedEventHandler(AddressOf Elapsed)
        t.Start()
    End Sub

    Private Sub Elapsed(ByVal sender As Object, ByVal e As ElapsedEventArgs)

        Dim timer1 As Timers.Timer = DirectCast(sender, Timers.Timer)

        Try
            ' disable temporarily
            timer1.Stop()
            _quemanager.StartProcessing()
            Thread.Sleep(1000)
        Finally
            ' make sure that the handler is always reenables
            timer1.Start()
        End Try
    End Sub

Namespace Managers

    Public Class QueueManager

        Private ReadOnly _items As New Queue

        Public Sub StartProcessing()

            For Each x In From i In File.GetAllAccountFolders() From x1 In File.CheckFolderForFiles(i & "\In") Select x1
                _items.Enqueue(x)
            Next

            Dim t1 As New Threading.Thread(AddressOf Process)

            t1.Start()
        End Sub

        Private Sub Process()
            Do
                SyncLock _items.SyncRoot
                    If _items.Count = 0 Then
                        'No more items.
                        Logger.Log("QueueManager", "Process", "No Items In Queue")
                        Exit Do
                    End If
                    Logger.Log("QueueManager", "Process", "Processing File: " & _items.Peek)
                    FileProcessingManager.ProcessFile(_items.Peek)
                    _items.Dequeue()
                End SyncLock
            Loop
        End Sub

    End Class
End Namespace

the logic behind this should be that the timer elapses every 10 seconds stops the timer runs the queue then when the queue has finished it should then start the timer again am i rite in thinking this? and theres no way the timer could restart its self untill the queue has finished?

Thanks

Answer 1

In your example code, QueueManager. StartProcessing starts a new thread in which to process the items in the queue. That means it will return immediately, likely before the queue is processed. Then, in the timer elapsed event handler, you restart the timer after a one second delay. So, if the queue takes longer than one second to process, then the timer will indeed get re-enabled before the queue processing is complete. In this situation, I would remove that one second sleep entirely, and have the QueueManager raise an event when it is done. Then your form could just watch for that event, and when it is raised, it could re-enable the timer in the event handler. You will need to do a Me.Invoke to get back on the UI thread first, though, before touching the properties of the timer.

Public Class Form1
    Private WithEvents _quemanager As New QueueManager()
    Private WithEvents _t As New Timers.Timer(10000)

    Private Sub Form1Load(ByVal sender As Object, ByVal e As EventArgs) Handles MyBase.Load
        t.Start()
    End Sub

    Private Sub _t_Elapsed(ByVal sender As Object, ByVal e As ElapsedEventArgs) Handles _t.Elapsed
        ' disable temporarily
        _t.Stop()
        _quemanager.StartProcessing()
    End Sub

    Private Sub _quemanager_ProcessingCompleted() Handles _quemanager.ProcessingCompleted
        _t.Start()
    End Sub
End Class

Public Class QueueManager
    Private ReadOnly _items As New Queue
    Public Event ProcessingCompleted()

    Public Sub StartProcessing()
        '...
    End Sub

    Private Sub Process()
        Do
            '...
        Loop
        RaiseEvent ProcessingCompleted()
    End Sub
End Class