CODEWITHSUNDEEP
perlstatic-analysiscall-graph
Paul Nathan
Paul Nathan

Reputation: 40299

How can I make a static analysis call graph for Perl?

I am working on a moderately complex Perl program. As a part of its development, it has to go through modifications and testing. Due to certain environment constraints, running this program frequently is not an option that is easy to exercise.

What I want is a static call-graph generator for Perl. It doesn't have to cover every edge case(e,g., redefining variables to be functions or vice versa in an eval).

(Yes, I know there is a run-time call-graph generating facility with Devel::DprofPP, but run-time is not guaranteed to call every function. I need to be able to look at each function.)

Upvotes: 12

Views: 4866

Answers (5)

Chris Koknat
Chris Koknat

Reputation: 3451

I solved a similar problem recently, and would like to share my solution.
This tool was born out of desperation, untangling an undocumented part of a 30,000-line legacy script, in order to implement an urgent bug fix.

It reads the source code(s), uses GraphViz to generate a png, and then displays the image on-screen.
Since it uses simple line-by-line regexes, the formatting must be "sane" so that nesting can be determined.
If the target code is badly formatted, run it through a linter first.
Also, don't expect miracles such as parsing dynamic function calls.

The silver lining of a simple regex engine is that it can be easily extended for other languages.
The tool now also supports awk, bash, basic, dart, fortran, go, lua, javascript, kotlin, matlab, pascal, perl, php, python, r, raku, ruby, rust, scala, swift, and tcl.

https://github.com/koknat/callGraph

Upvotes: 1

Brad Gilbert
Brad Gilbert

Reputation: 34110

I don't think there is a "static" call-graph generator for Perl.

The next closest thing would be Devel::NYTProf.

The main goal is for profiling, but it's output can tell you how many times a subroutine has been called, and from where.

If you need to make sure every subroutine gets called, you could also use Devel::Cover, which checks to make sure your test-suite covers every subroutine.

Upvotes: 4

Shaun
Shaun

Reputation: 101

I recently stumbled across a script while trying to solve find an answer to this same question. The script (linked to below) uses GraphViz to create a call graph of a Perl program or module. The output can be in a number of image formats.

http://www.teragridforum.org/mediawiki/index.php?title=Perl_Static_Source_Code_Analysis

Upvotes: 2

Chas. Owens
Chas. Owens

Reputation: 64909

Can't be done in the general case:

my $obj    = Obj->new;
my $method = some_external_source();

$obj->$method();

However, it should be fairly easy to get a large number of the cases (run this program against itself):

#!/usr/bin/perl

use strict;
use warnings;

sub foo {
    bar();
    baz(quux());
}

sub bar {
    baz();
}

sub baz {
    print "foo\n";
}

sub quux {
    return 5;
}

my %calls;

while (<>) {
    next unless my ($name) = /^sub (\S+)/;
    while (<>) {
        last if /^}/;
        next unless my @funcs = /(\w+)\(/g;
        push @{$calls{$name}}, @funcs;
    }
}

use Data::Dumper;
print Dumper \%calls;

Note, this misses

  • calls to functions that don't use parentheses (e.g. print "foo\n";)
  • calls to functions that are dereferenced (e.g. $coderef->())
  • calls to methods that are strings (e.g. $obj->$method())
  • calls the putt the open parenthesis on a different line
  • other things I haven't thought of

It incorrectly catches

  • commented functions (e.g. #foo())
  • some strings (e.g. "foo()")
  • other things I haven't thought of

If you want a better solution than that worthless hack, it is time to start looking into PPI, but even it will have problems with things like $obj->$method().

Just because I was bored, here is a version that uses PPI. It only finds function calls (not method calls). It also makes no attempt to keep the names of the subroutines unique (i.e. if you call the same subroutine more than once it will show up more than once).

#!/usr/bin/perl

use strict;
use warnings;

use PPI;
use Data::Dumper;
use Scalar::Util qw/blessed/;

sub is {
    my ($obj, $class) = @_;
    return blessed $obj and $obj->isa($class);
}

my $program = PPI::Document->new(shift);

my $subs = $program->find(
    sub { $_[1]->isa('PPI::Statement::Sub') and $_[1]->name }
);

die "no subroutines declared?" unless $subs;

for my $sub (@$subs) {
    print $sub->name, "\n";
    next unless my $function_calls = $sub->find(
        sub { 
            $_[1]->isa('PPI::Statement')             and
            $_[1]->child(0)->isa("PPI::Token::Word") and
            not (
                $_[1]->isa("PPI::Statement::Scheduled") or
                $_[1]->isa("PPI::Statement::Package")   or
                $_[1]->isa("PPI::Statement::Include")   or
                $_[1]->isa("PPI::Statement::Sub")       or
                $_[1]->isa("PPI::Statement::Variable")  or
                $_[1]->isa("PPI::Statement::Compound")  or
                $_[1]->isa("PPI::Statement::Break")     or
                $_[1]->isa("PPI::Statement::Given")     or
                $_[1]->isa("PPI::Statement::When")
            )
        }
    );
    print map { "\t" . $_->child(0)->content . "\n" } @$function_calls;
}

Upvotes: 8

DVK
DVK

Reputation: 129363

I'm not sure it is 100% feasible (since Perl code can not be statically analyzed in theory, due to BEGIN blocks and such - see very recent SO discussion). In addition, subroutine references may make it very difficult to do even in places where BEGIN blocks don't come into play.

However, someone apparently made the attempt - I only know of it but never used it so buyer beware.

Upvotes: 4

Related Questions