CODEWITHSUNDEEP
arraysloopsnested2dmips
user1802890
user1802890

Reputation: 33

Traversing through a 2D array in MIPS

Hey guys I am required to do C[i][j] = A[i][j] + B[j][i] for all i and j, size is 16 x 16 in a 2D array.

This is the main part of my code (shown below).

When I run this code in SPIM, I received an exception at line "lw $t4, 0($t4) # value of B[j][i]", which says bad address at data/stack read

When I checked the value stored in each registers, I realized that i == 0x1, but j reaches 0xbf0! (That's 3056)

I have no idea why this happened since my j is supposed to only increase from 0 to 15. Help me out! 

la    $t0, A                 # $t0 represents start address of A[i][j]
la    $t1, B                 # $t1 represents start address of B[i][j]
la    $t2, C                 # $t2 represents start address of C[i][j]  displacement of A will be the same as C                         

addi   $t3, $zero, 16         # set maximum iteration to be 16
addi   $t5, $zero, 0     # set i = 0
addi   $t6, $zero, 0     # set j = 0

loopi:
jal    loopj             # starts inner loopj
addi   $t5, $t5, 1       # i++
bne    $t3, $t5, loopi   # continue loopi if i < 16  
j      finish            

loopj:
sll    $t7, $t5, 4       
add    $t7, $t7, $t6
sll    $t7, $t7, 2       # 4 * ((i * 16) + j)  
add    $t9, $t7, $t0     # address of A[i][j]
lw     $t9, 0($t9)       # value of A[i][j]

sll    $t4, $t6, 4       
add    $t4, $t4, $t5
sll    $t4, $t4, 2       # 4 * ((j * 16) + i)
add    $t4, $t4, $t1     # address of B[j][i]
lw     $t4, 0($t4)       # value of B[j][i]

add    $t4, $t4, $t9     # A[i][j] + B[j][i] 

add    $t7, $t7, $t2     # address of C[i][j]
sw     $t4, 0($t7)       # store answer into C[i][j] 

addi   $t6, $t6, 1       # j++
bne    $t3, $t6, loopj   # continue loopj if j < 16
jr $ra

finish:

Upvotes: 2

Views: 8711

Answers (1)

gusbro
gusbro

Reputation: 22585

You forgot to reset j to zero every time you enter loopi, otherwise after the first loopj won't start at zero in loopj...

To fix it, you can move the addi which sets $t6 (which holds j) after the label loopi: 

loopi:
  addi   $t6, $zero, 0     # set j = 0
  jal    loopj             # starts inner loopj
   ...

Upvotes: 2

Related Questions