CODEWITHSUNDEEP
functional-programmingerlanganonymous-function
Jimmy Hoffa
Jimmy Hoffa

Reputation: 5967

Erlang syntax for nested function with if

I've been looking around and can't find examples of this and all of my syntax wrestling skills are failing me. Can someone please tell me how to make this compile?? My ,s ;s or .s are just wrong I guess for defining a nested function...

I'm aware there is a function for doing string replaces already so I don't need to implement this, but I'm playing with Erlang trying to pick it up so I'm hand spinning some of the basics I need to use..

replace(Whole,Old,New) ->
    OldLen = length(Old),
    ReplaceInit = fun(Next, NewWhole) ->
              if
                  lists:prefix(Old, [Next|NewWhole]) -> {_,Rest} = lists:split(OldLen-1, NewWhole), New ++ Rest;
                  true -> [Next|NewWhole]
              end,
    lists:foldr(ReplaceInit, [], Whole).

Basically I'm trying to write this haskell (also probably bad but beyond the point):

repl xs ys zs =
  foldr replaceInit [] xs
  where
    ylen = length ys
    replaceInit y newxs
      | take ylen (y:newxs) == ys = zs ++ drop (ylen-1) newxs
      | otherwise = y:newxs

Upvotes: 1

Views: 2538

Answers (1)

rvirding
rvirding

Reputation: 20916

The main problem is that in an if you are only allowed to use guards as tests. Guards are very restricted and, amongst other things, calls to general Erlang functions are not allowed. Irrespective of whether they are part of the OTP release or written by you. The best solution for your function is to use case instead of if. For example:

replace(Whole,Old,New) ->
    OldLen = length(Old),
    ReplaceInit = fun (Next, NewWhole) ->
                      case lists:prefix(Old, [Next|NewWhole]) of
                          true ->
                              {_,Rest} = lists:split(OldLen-1, NewWhole),
                              New ++ Rest;
                          false -> [Next|NewWhole]
                      end
                  end,
    lists:foldr(ReplaceInit, [], Whole).

Because of this if is not used that often in Erlang. See about if and about guards in the Erlang documentation.

Upvotes: 7

Related Questions