CODEWITHSUNDEEP
c++iosimportincludeobjective-c++
fatfreddyscat
fatfreddyscat

Reputation: 835

How to include C++ headers in an Objective C++ header?

I have a .cpp/.hpp file combo -> the .hpp file has #include ..

I also have a .mm/.h file combo -> if I include the .hpp file within my .mm Objective C++ file, there are no issues. However, if I try to include the .hpp file within my .h (Objective C header) file, I get a preprocessor issue 'iostream not found'.

Is there any way around this other than doing funky stuff like having a void* in my Objective C .h file and then casting it as the type that is included in the .mm or wrapping every C++ type within an Objective C++ type?

My question is basically the same as Tony's question (but nobody answered his):

https://stackoverflow.com/questions/10163322/how-to-include-c-header-file-in-objective-c-header-file

Upvotes: 16

Views: 18926

Answers (3)

MartinMoizard
MartinMoizard

Reputation: 6690

To use C++ in an Objective-C++ header file make sure to:

  1. Have a .h/.mm couple (Objective-C++)
  2. In the identity of your file, have the type set to Objective-C++ Source (it should be automatic)
  3. Include the considered file only from Objective-C++ source files. This point is obvious but can be very quickly forgotten and hard to track down

Upvotes: 4

Joe
Joe

Reputation: 57179

The problem is that you have to avoid all C++ semantics in the header to allow normal Objective-C classes to include it. This can be accomplished using opaque pointers.

CPPClass.h

class CPPClass
{
public:
    int getNumber()
    {
        return 10;
    }
};

ObjCPP.h

//Forward declare struct
struct CPPMembers;

@interface ObjCPP : NSObject
{
    //opaque pointer to store cpp members
    struct CPPMembers *_cppMembers;
}

@end

ObjCPP.mm

#import "ObjCPP.h"
#import "CPPClass.h"

struct CPPMembers {
    CPPClass member1;
};

@implementation ObjCPP

- (id)init
{
    self = [super init];
    if (self) {
        //Allocate storage for members
        _cppMembers = new CPPMembers;

        //usage
        NSLog(@"%d", _cppMembers->member1.getNumber());
    }

    return self;
}

- (void)dealloc
{
    //Free members even if ARC.
    delete _cppMembers;

    //If not ARC uncomment the following line
    //[super dealloc];
}

@end

Upvotes: 26

RonaldBarzell
RonaldBarzell

Reputation: 3830

The #include directive simply includes text; the only time Objective C will complain is if there is something in the include file that is not valid Objective C.

In your case, it gives you the answer; the iostream.h header file is not found in Objective C. Find where this file is referenced and remove the #include to it.

Upvotes: 0

Related Questions