CODEWITHSUNDEEP
groovy
vv.
vv.

Reputation: 65

Groovy - bind properties from one object to another

Is there a way to bind properties from one instance of a class to the properties of an instance of another class (the common fields between the two). See the example below:

class One {
  String foo
  String bar
}

class Two {
  String foo
  String bar
  String baz
}

def one = new One(foo:'one-foo', bar:'one-bar')
def two = new Two()

two.properties = one.properties

assert "one-foo" == two.foo
assert "one-bar" == two.bar
assert !two.baz

The result is an error: Cannot set readonly property: properties for class: Two

Upvotes: 4

Views: 9640

Answers (2)

Michal Zmuda
Michal Zmuda

Reputation: 5621

I would choose InvokerHelper.setProperties as I suggesed here.

use(InvokerHelper) {
    two.setProperties(one.properties)
}

Upvotes: 9

Dónal
Dónal

Reputation: 187499

The problem is that for every object, .properties includes two built-in Groovy-defined properties, these are the metaClass and class. What you want to do is only set the user-defined properties. You can easily do this using code such as that shown below:

class One {
  String foo
  String bar
}

class Two {
  String foo
  String bar
  String baz
}

def one = new One(foo:'one-foo', bar:'one-bar')

// You'll probably want to define a helper method that does the following 3 lines for any Groovy object
def propsMap = one.properties
propsMap.remove('metaClass')
propsMap.remove('class')

def two = new Two(propsMap)

assert "one-foo" == two.foo
assert "one-bar" == two.bar
assert !two.baz

Upvotes: 6

Related Questions