CODEWITHSUNDEEP
vb.net
Wine Too
Wine Too

Reputation: 4655

Navigating with arrow keys in vb.net

I'm trying to make navigation through controls with arrow keys (up/down).
To try my example just create a new form1 and paste this code into it. 

Public Class Form1

Private Sub Form1_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load

    Dim tb As New TextBox
    Dim cb As New CheckBox
    Dim cbb As New ComboBox
    Dim b1 As New Button
    Dim b2 As New Button

    With Me
        .KeyPreview = True
        .Size = New Size(350, 200)
        With .Controls
            .Add(tb)
            With tb
                .TabIndex = 0
                .Location = New Point(95, 20)
                .Text = "This is"
            End With
            .Add(cb)
            With cb
                .TabIndex = 1
                .Location = New Point(95, 50)
                .Checked = True
                .Text = "Example checkbox"
                .AutoSize = True
            End With
            .Add(cbb)
            With cbb
                .TabIndex = 2
                .Location = New Point(95, 80)
                .Text = "an Example"
                .DropDownStyle = ComboBoxStyle.DropDownList
            End With
            .Add(b1)
            With b1
                .TabStop = False
                .Location = New Point(90, 130)
                .Text = "Nothing"
            End With
            .Add(b2)
            With b2
                .TabStop = False
                .Location = New Point(170, 130)
                .Text = "Exit"
                AddHandler b2.Click, AddressOf b2_Click
            End With
        End With
    End With
End Sub

Private Sub Form1_KeyDown(ByVal sender As Object, ByVal e As System.Windows.Forms.KeyEventArgs) Handles Me.KeyDown
    If e.KeyCode = Keys.Up Then
        e.Handled = True
        Me.SelectNextControl(Me.ActiveControl, False, True, True, True)
    End If

    If e.KeyCode = Keys.Down Then
        e.Handled = True
        Me.SelectNextControl(Me.ActiveControl, True, True, True, True)
    End If
End Sub

Private Sub b2_Click(ByVal sender As Object, ByVal e As System.EventArgs)
    Me.Close()
End Sub

End Class

What happens?
When starting a program and navigating with arrows there havent 'focus rect' around controls and in some situation focus "run's out" to controls with tabstop = false??

But...

If I pass once with TAB key through controls after that navigating with arrows becomes good, focus rect appear's and everything is OK.

What may be problem here? What to do that navigating with arrows behaves a same like with tab key immediately after program starts?

Upvotes: 0

Views: 2051

Answers (1)

Wine Too
Wine Too

Reputation: 4655

I find a solution to get things working as expected "through code" here: C# code

And here is my translation to VB.
1) In some your public module add imports...

Imports System.Runtime.InteropServices

2) Put this declarations in same module:

<DllImport("user32.dll")> _
Private Sub SystemParametersInfo(ByVal uiAction As UInteger, ByVal uiParam As UInteger, ByRef pvParam As Integer, ByVal fWinIni As UInteger)
End Sub

' Constants used for User32 calls. 
Const SPI_SETKEYBOARDCUES As UInteger = &H100B

3) Put this public function in same module:

''' <summary> 
''' Change the setting programmatically 
''' for keyboard shortcut Issue 
''' </summary> 
Public Sub GetAltKeyFixed()
    Dim pv As Integer = 1
    ' Call to systemparametersinfo to set true of pv variable.

    SystemParametersInfo(SPI_SETKEYBOARDCUES, 0, pv, 0)
    'Set pvParam to TRUE to always underline menu access keys, 
End Sub

4) From start place of your program (say Form1) just call:

GetAltKeyFixed()

Once is enough :)

Upvotes: 1

Related Questions