CODEWITHSUNDEEP
grailsscriptingdatabase-migration
John Ormerod
John Ormerod

Reputation: 117

grails: guidance on writing scripts, esp for calling existing database-migration scripts

My requirement is to invoke some processing from a Jenkins build server, to determine whether the domain model has changed since the last build. I've come to the conclusion that the way forward is to write a script that will invoke a sequence of existing scripts from the db-migration plugin. Then I can invoke it in the step that calls test-app and war.

I've looked in the Grails doc, and at some of the db-migration scripts, and I find I'm stuck - have no idea where to start trying things. I'd be really grateful if someone could point me at any suitable sources. BTW, I'm a bit rusty in Grails. Started to teach myself two years ago via proof of concept project, which lasted 6 months. Then it was back to Eclipse rich client work. That might be part of my problem, though I never go involved in scripts.

One thing I need in the Jenkins evt is to get hold of the current SVN revision number being used for the build. Suggestions welcome.

Regards, John

Upvotes: 0

Views: 1435

Answers (1)

Burt Beckwith
Burt Beckwith

Reputation: 75671

Create a new script by running grails create-script scriptname. The database-migration plugins scripts are configured to be easily reused. There are is a lot of shared code in _DatabaseMigrationCommon.groovy and each script defines one target with a unique name. So you can import either the shared script or any standalone script (or multiple scripts) and call the targets like they're methods.

By default the script generated by create-script "imports" the _GrailsInit script via includeTargets << grailsScript("_GrailsInit") and you can do the same, taking advantage of the magic variables that point at installed plugins' directories:

includeTargets << new File("$databaseMigrationPluginDir/scripts/DbmGenerateChangelog.groovy")

If you do this you can remove the include of _GrailsInit since it's already included, but if you don't that's fine since Grails only includes files once.

Then you can define your target and call any of the plugin's targets. The targets cannot accept parameters, but you can add data to the argsMap (this is a map Grails creates from the parsed commandline arguments) to simulate user-specified args. Note that any args passed to your script will be seen by the database-migration plugin's scripts since they use the same argsMap.

Here's an example script that just does the same thing as dbm-generate-changelog but adds a before and after message:

includeTargets << new File("$databaseMigrationPluginDir/scripts/DbmGenerateChangelog.groovy")

target(foo: "Just calls dbmGenerateChangelog") {
   println 'before'
   dbmGenerateChangelog()
   println 'after'
}

setDefaultTarget foo

Note that I renamed the target from main to foo so it's unique, in case you want to call this from another script.

As an example of working with args, here's a modified version that specifies a default changelog name if none is provided:

println 'before'
if (!argsMap.params) {
   argsMap.params = ['foo2.groovy']
}
dbmGenerateChangelog()
println 'after'

Edit: Here's a fuller example that captures the output of dbm-gorm-diff to a string:

includeTargets << new File("$databaseMigrationPluginDir/scripts/_DatabaseMigrationCommon.groovy")

target(foo: "foo") {
   depends dbmInit

   def configuredSchema = config.grails.plugin.databasemigration.schema
   String argSchema = argsMap.schema
   String effectiveSchema = argSchema ?: configuredSchema ?: defaultSchema

   def realDatabase
   boolean add = false // booleanArg('add')
   String filename = null // argsList[0]

   try {
      printMessage "Starting $hyphenatedScriptName"

      ByteArrayOutputStream baos = new ByteArrayOutputStream()
      def baosOut = new PrintStream(baos)

      ScriptUtils.executeAndWrite filename, add, dsName, { PrintStream out ->
         MigrationUtils.executeInSession(dsName) {
            realDatabase = MigrationUtils.getDatabase(effectiveSchema, dsName)
            def gormDatabase = ScriptUtils.createGormDatabase(dataSourceSuffix, config, appCtx, realDatabase, effectiveSchema)
            ScriptUtils.createAndPrintFixedDiff(gormDatabase, realDatabase, realDatabase, appCtx, diffTypes, baosOut)
         }
      }

      String xml = new String(baos.toString('UTF-8'))
      def ChangelogXml2Groovy = classLoader.loadClass('grails.plugin.databasemigration.ChangelogXml2Groovy')
      String groovy = ChangelogXml2Groovy.convert(xml)

      // do something with the groovy or xml here

      printMessage "Finished $hyphenatedScriptName"
   }
   catch (e) {
      ScriptUtils.printStackTrace e
      exit 1
   }
   finally {
      ScriptUtils.closeConnection realDatabase
   }
}

setDefaultTarget foo

Upvotes: 1

Related Questions