CODEWITHSUNDEEP
serializationgroovydeserialization
Doug Harris
Doug Harris

Reputation: 3369

Serializing groovy map to string with quotes

I'm trying to persist a groovy map to a file. My current attempt is to write the string representation out and then read it back in and call evaluate on it to recreate the map when I'm ready to use it again.

The problem I'm having is that the toString() method of the map removes vital quotes from the values of the elements. When my code calls evaluate, it complains about an unknown identifier.

This code demonstrates the problem:

m = [a: 123, b: 'test']
print "orig: $m\n"

s = m.toString()
print " str: $s\n"

m2 = evaluate(s)
print " new: ${m2}\n"

The first two print statements almost work -- but the quotes around the value for the key b are gone. Instead of showing [a: 123, b: 'test'], it shows [a: 123, b: test].

At this point the damage is done. The evaluate call chokes when it tries to evaluate test as an identifier and not a string.

So, my specific questions:

  1. Is there a better way to serialize/de-serialize maps in Groovy?
  2. Is there a way to produce a string representation of a map with proper quotes?

Upvotes: 32

Views: 53667

Answers (2)

ataylor
ataylor

Reputation: 66059

Groovy provides the inspect() method returns an object as a parseable string:

// serialize
def m = [a: 123, b: 'test']
def str = m.inspect()

// deserialize
m = Eval.me(str)

Another way to serialize a groovy map as a readable string is with JSON:

// serialize
import groovy.json.JsonBuilder
def m = [a: 123, b: 'test']
def builder = new JsonBuilder()
builder(m)
println builder.toString()

// deserialize
import groovy.json.JsonSlurper
def slurper = new JsonSlurper()
m = slurper.parseText('{"a": 123, "b": "test"}')

Upvotes: 76

DMoney
DMoney

Reputation: 71

You can use myMap.toMapString()

Upvotes: 6

Related Questions