XSLT How to apply recursion to transform from a flat file to a nested tree

Question

I know that there are several other question/answers similar to this, but I haven't read one that addresses my confusion over this transform. I need to move an XML document from this format:

<root>
    <row>
        <t0>1</t0>
        <title>Main Title</title>
    </row>
    <row>
        <t0>2</t0>
        <title>Secondary Title</title>
        <note>Note</note>
    </row>
    <row>
        <t0>3</t0>
        <title>Tertiary Title</title>
    </row>
    <row>
        <t0>3</t0>
        <title>Another Title</title>
    </row>
    <row>
        <t0>2</t0>
        <title>A Second Secondary Title</title>
        <note>Note</note>
    </row>
    <row>  
        <t0>3</t0>
        <title>Third Level Title</title>
    </row>
    <row> 
        <t0>3</t0>
        <title>Title at Level Three</title>
    </row>
</root>

to this format:

<root>
    <header>List</header>
    <t01>
        <title>Main Title</title>
        <t02>
            <title>Secondary Title</title>
            <note>Note</note>
            <t03>
                <title>Tertiary Title</title>
            </t03>
            <t03>
                <title>Another Title</title>
            </t03>
        </t02>
        <t02>
            <title>A Second Secondary Title</title>
            <note>Note</note>
            <t03>
                <title>Third Level Title</title>
            </t03>
            <t03>   
                <title>Title at Level Three</title>
            </t03>
        </t02>
    </t01>
</root>

I'm using XSLT 2.0 and I'm getting hung up on applying for-each-group recursively. Thanks for your time & trouble.

Answer 1

With XSLT 2.0 I would strongly suggest to use the for-each-grouping together with a recursive function or template; below is a sample using a function:

<xsl:stylesheet
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  version="2.0"
  xmlns:xs="http://www.w3.org/2001/XMLSchema"
  xmlns:mf="http://example.com/mf"
  exclude-result-prefixes="xs mf">

<xsl:output indent="yes"/>

<xsl:function name="mf:group" as="element()*">
  <xsl:param name="elements" as="element(row)*"/>
  <xsl:param name="level" as="xs:integer"/>
  <xsl:for-each-group select="$elements" group-starting-with="row[t0 = $level]">
    <xsl:element name="t{format-number($level, '00')}">
      <xsl:copy-of select="* except t0"/>
      <xsl:sequence select="mf:group(current-group() except ., $level + 1)"/>
    </xsl:element>
  </xsl:for-each-group>
</xsl:function>

<xsl:template match="root">
  <xsl:copy>
    <header>List</header>
    <xsl:sequence select="mf:group(row, 1)"/>
  </xsl:copy>
</xsl:template>

</xsl:stylesheet>

Answer 2

Please give this a try:

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:output method="xml" indent="yes"/>

  <xsl:template match="@* | node()">
    <xsl:copy>
      <xsl:apply-templates select="@* | node()"/>
    </xsl:copy>
  </xsl:template>

  <xsl:template match="/root">
    <root>
      <header>List</header>
      <xsl:apply-templates select="row[t0 = 1]" />
    </root>
  </xsl:template>

  <xsl:template match="row">
    <xsl:variable name="level" select="t0" />

    <xsl:element name="{concat('t0', $level)}">
      <xsl:apply-templates select="title | note" />
      <xsl:variable name="nextPeer" 
            select="following-sibling::row[t0 &lt;= $level]" />
      <xsl:variable name="children" 
            select="following-sibling::row[t0 = $level + 1][not($nextPeer) 
                 or (count(preceding-sibling::row) &lt; count($nextPeer[1]/preceding-sibling::row))]" />

      <xsl:apply-templates select="$children" />
    </xsl:element>
  </xsl:template>
</xsl:stylesheet>