CODEWITHSUNDEEP
windowsdelphifile
Serkan
Serkan

Reputation:

How to get create/last modified dates of a file in Delphi?

I want to get a files these attributes as integer values.

Upvotes: 12

Views: 33260

Answers (7)

OregonGhost
OregonGhost

Reputation: 23759

Delphians tend to like the FindFirst approach (the SearchRec structure has some of those), but I'd suggest the Win32 API function GetFileAttributesEx.

Upvotes: 13

thvedel
thvedel

Reputation: 71

System.IOUtils do have a TFile record with several functions for getting file age, e.g. GetCreationTime, GetLastAccessTime, GetLastWriteTime

Upvotes: 6

Ian Murphy
Ian Murphy

Reputation: 53

function GetFileModDate(filename : string) : TDateTime;
var
   F : TSearchRec;
begin
   FindFirst(filename,faAnyFile,F);
   Result := F.TimeStamp;
   //if you really wanted an Int, change the return type and use this line:
   //Result := F.Time;
   FindClose(F);
end;

F.Time has since been Deprecated, Help file says Use F.TimeStamp.
Just to update this due to later versions of Delphi

Upvotes: 5

JosephStyons
JosephStyons

Reputation: 58685

This should work, and it is native Delphi code.

function GetFileModDate(filename : string) : integer;
var
  F : TSearchRec;
begin
  FindFirst(filename,faAnyFile,F);
  Result := F.Time;
  //if you wanted a TDateTime, change the return type and use this line:
  //Result := FileDateToDatetime(F.Time);
  FindClose(F);
end;

Upvotes: 4

gabr
gabr

Reputation: 26830

From the DSiWin32 freeware library:

function DSiFileTimeToDateTime(fileTime: TFileTime; var dateTime: TDateTime): boolean;
var
  sysTime: TSystemTime;
begin
  Result := FileTimeToSystemTime(fileTime, sysTime);
  if Result then
    dateTime := SystemTimeToDateTime(sysTime);
end; { DSiFileTimeToDateTime }

function  DSiGetFileTimes(const fileName: string; var creationTime, lastAccessTime,
  lastModificationTime: TDateTime): boolean; 
var
  fileHandle            : cardinal;
  fsCreationTime        : TFileTime;
  fsLastAccessTime      : TFileTime;
  fsLastModificationTime: TFileTime;
begin
  Result := false;
  fileHandle := CreateFile(PChar(fileName), GENERIC_READ, FILE_SHARE_READ, nil,
    OPEN_EXISTING, 0, 0);
  if fileHandle <> INVALID_HANDLE_VALUE then try
    Result :=
      GetFileTime(fileHandle, @fsCreationTime, @fsLastAccessTime,
         @fsLastModificationTime) and
      DSiFileTimeToDateTime(fsCreationTime, creationTime) and
      DSiFileTimeToDateTime(fsLastAccessTime, lastAccessTime) and
      DSiFileTimeToDateTime(fsLastModificationTime, lastModificationTime);
  finally
    CloseHandle(fileHandle);
  end;
end; { DSiGetFileTimes }

Upvotes: 9

Toon Krijthe
Toon Krijthe

Reputation: 53366

Try 

function FileAge(const FileName: string; out FileDateTime: TDateTime): Boolean;

From SysUtils.

Upvotes: 15

Lars Truijens
Lars Truijens

Reputation: 43595

You could call the GetFileInformationByHandle winapi function. Aparently JCL has a GetFileLastWrite function you could also use

Upvotes: 0

Related Questions