CODEWITHSUNDEEP
windowsstringbatch-filesplit
Ryan Shrout
Ryan Shrout

Reputation: 19

How to split a string in a Windows batch files?

I am trying to split and make a new string in a Windows batch file but I can't figure out how to do it.

I am trying to convert this:

Crysis3_2560x1440

To this:

Crysis 3 - 2560x1440

And then:

HD7970CrossFire

To this:

HD 7970 CrossFire

Any suggestions?

Upvotes: 0

Views: 4010

Answers (2)

Aacini
Aacini

Reputation: 67216

EDIT: This is the new version that manage the special cases mentioned in comments:

@echo off
setlocal EnableDelayedExpansion

for /F %%a in (inputFile.txt) do (
   set string=%%a
   echo Original: !string!
   call :Splint string
   echo Modified: !string!
)
goto :EOF

:Splint string
set string=!%1!
rem Change underscore by space-dash-space
set string=%string:_= - %
rem Separate the string at first group of digits or space
for /F "tokens=1* delims=0123456789 " %%a in ("%string%") do (
   set first=%%a
   set last=%%b
)
rem Eliminate first part from middle
set middle=!string:%first%=!
rem Eliminate last part from middle, if exists
if defined last set middle=!middle:%last%=!
rem Eliminate spaces from middle
set middle=%middle: =%
rem Assemble the result
if defined middle (
   set %1=%first% %middle% %last%
) else (
   set %1=%first% %last%
)
exit /B

Output:

Original: Crysis3_2560x1440
Modified: Crysis 3 - 2560x1440
Original: HD7970CrossFire
Modified: HD 7970 CrossFire
Original: Skyrim_2560x1440
Modified: Skyrim - 2560x1440
Original: SleepingDogs_2560x1440
Modified: SleepingDogs - 2560x1440
Original: GTX680
Modified: GTX 680

Antonio

Upvotes: 2

BDM
BDM

Reputation: 3900

You could use these snippets as a base...

set in=Crysis3_2560x1440
set out=!in:_= - !
set in
set out

And...

set in=HD7970CrossFire
set out=!in:HD7970CrossFire=HD 7970 CrossFire!
set in
set out

Although I just don't see why you don't just go

set str=HD 7970 CrossFire

Upvotes: 1

Related Questions