CODEWITHSUNDEEP
xsltxslt-2.0
Dirk
Dirk

Reputation: 121

Create a recursive string function for adding a sequence

I've a challenging problem and so far I wasn't able to solve.

Within my xlst I have variable which contains a string. I need to add the following sequence [eol] to this string. On a fix position namely every 65 characters

I thought to use a function or template to recursive add this charackter. The reason is that the string length can variate in length.

    <xsl:function name="funct:insert-eol" as="xs:string" >
    <xsl:param name="originalString" as="xs:string?"/>
    <xsl:variable name="length">
        <xsl:value-of select="string-length($originalString)"/>
    </xsl:variable>
    <xsl:variable name="start" as="xs:integer">
        <xsl:value-of select="1"/>
    </xsl:variable>
    <xsl:variable name="eol" as="xs:integer">
        <xsl:value-of select="65"/>
    </xsl:variable>
    <xsl:variable name="newLines">
        <xsl:value-of select="$length idiv number('65')"/>
    </xsl:variable>
    <xsl:for-each select="1 to $newLines">
        <xsl:value-of select="substring($originalString, $start, $eol)" />
    </xsl:for-each>
    </xsl:function>

The more I write code the more variables I need to introduce. This is still my lack on understanding.

For example we want every 5 chars an [eol]

aaaaaaabbbbbbccccccccc

aaaaa[eol]aabbb[eol]bbbcc[eol]ccccc[eol]cc

Hope someone has a starting point for me..

Regards Dirk

Upvotes: 3

Views: 726

Answers (3)

Dimitre Novatchev
Dimitre Novatchev

Reputation: 243529

Rather straight-forward and short -- no recursion is necessary (and can even be specified as a single XPath expression):

<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output method="text"/>
 <xsl:param name="pLLength" select="5"/>

 <xsl:template match="/*">
  <xsl:variable name="vText" select="string()"/>

  <xsl:for-each select="1 to string-length($vText) idiv $pLLength +1">
    <xsl:value-of select="substring($vText, $pLLength*(position()-1)+1, $pLLength)"/>
    <xsl:if test=
    "not(position() eq last()
       or position() eq last() and string-length($vText) mod $pLLength)">[eol]</xsl:if>
  </xsl:for-each>
 </xsl:template>
</xsl:stylesheet>

When this transformation is applied on this XML document:

<t>aaaaaaabbbbbbccccccccc</t>

the wanted, correct result is produced:

aaaaa[eol]aabbb[eol]bbbcc[eol]ccccc[eol]cc

When this XML document is processed:

<t>aaaaaaabbbbbbcccccccccddd</t>

again the wanted, correct result is produced:

aaaaa[eol]aabbb[eol]bbbcc[eol]ccccc[eol]ccddd[eol]

Upvotes: 2

Martin Honnen
Martin Honnen

Reputation: 167696

You can treat it as a grouping problem, using for-each-group:

<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  xmlns:xs="http://www.w3.org/2001/XMLSchema"
  xmlns:mf="http://example.com/mf"
  exclude-result-prefixes="xs mf">

<xsl:function name="mf:insert-eol" as="xs:string">
  <xsl:param name="input" as="xs:string"/>
  <xsl:param name="chunk-size" as="xs:integer"/>
  <xsl:value-of>
  <xsl:for-each-group select="string-to-codepoints($input)" group-by="(position() - 1) idiv $chunk-size">
    <xsl:if test="position() gt 1"><xsl:sequence select="'eol'"/></xsl:if>
    <xsl:sequence select="codepoints-to-string(current-group())"/>
  </xsl:for-each-group>
  </xsl:value-of>
</xsl:function>

<xsl:template match="@* | node()">
  <xsl:copy>
    <xsl:apply-templates select="@* , node()"/>
  </xsl:copy>
</xsl:template>

<xsl:template match="text">
  <xsl:copy>
    <xsl:sequence select="mf:insert-eol(., 5)"/>
  </xsl:copy>
</xsl:template>

</xsl:stylesheet>

That stylesheet transforms

<root>
  <text>aaaaaaabbbbbbccccccccc</text>
</root>

into

<root>
  <text>aaaaaeolaabbbeolbbbcceolccccceolcc</text>
</root>

Upvotes: 1

Navin Rawat
Navin Rawat

Reputation: 3138

Try this one:

<?xml version='1.0' ?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  xmlns:xs="http://www.w3.org/2001/XMLSchema">

  <xsl:param name="TextToChange" select="'aaaaaaabbbbbbccccccccc'"/>
  <xsl:param name="RequiredLength" select="xs:integer(5)"/>

  <xsl:template match="/">
    <xsl:call-template name="AddText"/>
  </xsl:template>

  <xsl:template name="AddText">
    <xsl:param name="Text" select="$TextToChange"/>
    <xsl:param name="TextLength" select="string-length($TextToChange)"/>
    <xsl:param name="start" select="xs:integer(1)"/>
    <xsl:param name="end" select="$RequiredLength"/>
    <xsl:choose>
      <xsl:when test="$TextLength gt $RequiredLength">
        <xsl:value-of select="substring($Text,$start,$end)"/>
        <xsl:text>[eol]</xsl:text>
        <xsl:call-template name="AddText">
          <xsl:with-param name="Text" select="substring-after($Text, substring($Text,$start,$end))"/>
          <xsl:with-param name="TextLength"
            select="string-length(substring-after($Text, substring($Text,$start,$end)))"/>
        </xsl:call-template>
      </xsl:when>
      <xsl:otherwise>
        <xsl:value-of select="$Text"/>
      </xsl:otherwise>
    </xsl:choose>

  </xsl:template>

</xsl:stylesheet>

Upvotes: 0

Related Questions