CODEWITHSUNDEEP
assemblyx86intelgnu-assembleratt
Alex
Alex

Reputation: 609

Why does switching from AT&T to Intel syntax make this tutorial segfault using GAS?

I'm working through some of the tutorials on http://www.ibm.com/developerworks/linux/library/l-gas-nasm/index.html to familiarize myself with x86/x64. This tutorial code compiles and runs without a hiccup using the provided code, which uses AT&T syntax:

.global main
.text
main:                               # This is called by C library's startup code
    mov     $message, %rdi          # First integer (or pointer) parameter in %edi
    call    puts                    # puts("Hello, World")
    ret                             # Return to C library code
message:
    .asciz "Hello, World"           # asciz puts a 0x00 byte at the end

However, when I convert this code to Intel syntax, I get a "Segmentation fault" error.

.intel_syntax noprefix
.global main
.text
main:                               # This is called by C library's startup code
    mov     rdi, message            # First integer (or pointer) parameter in %edi
    call    puts                    # puts("Hello, World")
    ret                             # Return to C library code
message:
    .asciz "Hello, World"           # asciz puts a 0x00 byte at the end

I'm not familiar with x86, so perhaps I'm missing something. Any ideas?

Upvotes: 11

Views: 2195

Answers (1)

Jens Björnhager
Jens Björnhager

Reputation: 5649

In AT&T syntax, mov $message, %rdi, the $ means immediate, meaning the address of message.

In GAS's Intel syntax, mov rdi, message means absolute addressing, meaning the content at message. To get the actual address of message, you need to supply the offset keyword: mov rdi, offset message.

Disassebly of the two binaries shows the difference:

AT&T:

0000000000000000 <main>:
0:   48 c7 c7 00 00 00 00    mov    $0x0,%rdi

Intel:

0000000000000000 <main>:
0:   48 8b 3c 25 00 00 00 00    mov    0x0,%rdi

Upvotes: 15

Related Questions