CODEWITHSUNDEEP
actionscript-3flash
David
David

Reputation: 5

On mouse click, call function?

I am having some difficulty figuring out how to get my animation to work so that when an object (movie clip) is clicked, a function is called and said function removes the object from the screen and shows an explosion. The code is below (From my EnemyShip.as file):

package
{
import flash.display.MovieClip;
import flash.events.Event;
import flash.utils.Timer;
import flash.events.MouseEvent;

public class EnemyShipMed extends MovieClip
{
    var speed:Number;

    function EnemyShipMed()
    {
        this.x = 800;
        this.y = Math.random() * 275 + 75;
        speed = Math.random()*5 + 6;
        addEventListener("enterFrame", enterFrame);
        addEventListener(MouseEvent.MOUSE_DOWN, mouseShoot);
    }

        function enterFrame(e:Event)
        {
            this.x -= speed;
            if(this.x < -100)
            {
                removeEventListener("enterFrame", enterFrame);
                stage.removeChild(this);
            }
        }

        function kill()
        {
            var explosion = new Explosion();
            stage.addChild(explosion);
            explosion.x = this.x;
            explosion.y = this.y;
            removeEventListener("enterFrame", enterFrame);
            stage.removeChild(this);
        }

        function mouseShoot(event:MouseEvent)
        {
            kill();
        }
    }
}

I have replaced the mouse pointer with a crosshair (Movie clip is called crosshair_mc). Here is what I have in my Main.as file:

package  {
import flash.display.MovieClip;
import flash.events.Event;
import flash.events.MouseEvent;
import flash.utils.Timer;
import flash.ui.Mouse;
import flash.media.Sound;
import flash.media.SoundChannel;

public class Main extends MovieClip {

public var crosshair:crosshair_mc;
var enemyShipTimer:Timer;
var enemyShipTimerMed:Timer;
var enemyShipTimerSmall:Timer;

public function Main()
{
    enemyShipTimer = new Timer(2000);
    enemyShipTimer.addEventListener("timer", sendEnemy);
    enemyShipTimer.start();

    enemyShipTimerMed = new Timer(2500);
    enemyShipTimerMed.addEventListener("timer", sendEnemyMed);
    enemyShipTimerMed.start();

    enemyShipTimerSmall = new Timer(2750);
    enemyShipTimerSmall.addEventListener("timer", sendEnemySmall);
    enemyShipTimerSmall.start();

    //This creates a new instance of the cursor movie clip and adds it onto
    //the stage using the addChild method.
    crosshair = new crosshair_mc();
    addChild(crosshair);

    //Hides the default cursor on the stage so it will not be shown.
    Mouse.hide();

    //Adds an event listener onto the stage with the enter frame event which
    //repeatedly executes the moveCursor function.
    stage.addEventListener(Event.ENTER_FRAME, moveCursor);
}

function sendEnemy(e:Event)
{
    var enemy = new EnemyShip();
    stage.addChild(enemy);
    stage.addChild(crosshair);//brings crosshair to topmost level on stage
}

function sendEnemyMed(e:Event)
{
    var enemymed = new EnemyShipMed();
    stage.addChild(enemymed);
    stage.addChild(crosshair);//brings crosshair to topmost level on stage
}

function sendEnemySmall(e:Event)
{
    var enemysmall = new EnemyShipSmall();
    stage.addChild(enemysmall);
    stage.addChild(crosshair);//brings crosshair to topmost level on stage
}
//This function set the x & y positions of the custom cursor to the x & y positions
//of the default cursor.
function moveCursor(event:Event) 
{
  crosshair.x=mouseX;
  crosshair.y=mouseY;
     }
   }
}

Thanks.

Upvotes: 0

Views: 561

Answers (1)

Kodiak
Kodiak

Reputation: 5978

My guess would be that your crosshair catches all the click events because it's always under the mouse. Set 

  crosshair_mc.mouseEnabled = crosshair_mc.mouseChildren = false;

to make it "transparent" for mouse events.

Upvotes: 1

Related Questions