CODEWITHSUNDEEP
linuxassemblykernel
user1198331
user1198331

Reputation: 139

How to use use as in linux with assembly language

I am studying Linux kernel, so I have to read some assembly code. Here is a sample code

SYSWRITE=4
.globl mywrite,myadd
.text
mywrite:
    pushl %ebp
    movl %esp,%ebp
    pushl %ebx
    movl 8(%ebp),%ebx
    movl 12(%ebp),%ecx
    movl 16(%ebp),%edx
    movl $SYSWRITE,%eax
    int $0x80
    popl %ebx
    movl %ebp,%esp
    popl %ebp
    ret

myadd:
    pushl %ebp
    movl %esp,%ebp
    movl 8(%ebp),%eax
    movl 12(%ebp),%edx
    xorl %ecx,%ecx
    addl %eax,%edx
    jo 1f
    movl 16(%ebp),%eax
    movl %edx,(%eax)
    incl %ecx
1:  
    movl %ecx,%eax
    movl %ebp,%esp
    popl %ebp
    ret

I use the as in this way
"as -o callee.o callee.s"
to compile it,but it fails with a message saying something like this
"callee.s|5| Error: suffix or operands invalid for `push'"

Upvotes: 1

Views: 130

Answers (1)

Carl Norum
Carl Norum

Reputation: 225262

You're probably on a 64-bit machine, so your as defaults to 64-bit. Since you have 32-bit code, you want to use:

as -32 -o callee.o callee.s

Upvotes: 3

Related Questions