CODEWITHSUNDEEP
excelvba
user803271
user803271

Reputation: 115

Create hyperlink to file on active sheet

I am trying to create a button which prompts the user for a file then creates a hyperlink in the active spreadsheet.

Goal: after the file is uploaded subsequent users can click on the hyperlink to view the file.

What I have tried, create an ActiveX control in Excel, but representing the input as a hyperlink output in a cell is the problem.

Private Sub CommandButton1_Click()

Dim sFullName As String
Application.FileDialog(msoFileDialogOpen).Show
sFullName = Application.FileDialog(msoFileDialogOpen).SelectedItems(1)
End Sub

Insert reference to pdfs

Sub InsertObjectAsIcon()
'lets user browse for a file to insert into the
'current active worksheet.
'all are inserted as icons, not "visible" objects, so
'to view they will need an appropriate viewer/reader
'at the recipient end.
'
'This one shows how you could set up to use
'several different icons depending on the type of file
'inserted.  You'll have to experiment by recording
'macros while inserting various file types to build
'up a list to use, just add new Case Is = statements
'do deal with the file types.  Be sure to enter the
'file type in all UPPERCASE.
'
  Dim iconToUse As String
  Dim fullFileName As String
  Dim FNExtension As String
  fullFileName = Application.GetOpenFilename("*.*, All Files", , , , False)

  If fullFileName = "False" Then
    Exit Sub ' user cancelled
  End If
'choose an icon based on filename extension
  'get all after last "." in filename
  FNExtension = Right(fullFileName, Len(fullFileName) - _
   InStrRev(fullFileName, "."))

  'select icon based on filename extension
  Select Case UCase(FNExtension)
    Case Is = "TXT"
      iconToUse = "C:\Windows\system32\packager.dll"

    Case Is = "XLS", "XLSM", "XLSX"
      iconToUse = "C:\Windows\Installer\{91140000-0011-0000-0000-0000000FF1CE}\xlicons.exe"

    Case Is = "PDF"
      iconToUse = "C:\Windows\Installer\{AC76BA86-1033-F400-7761-000000000004}\_PDFFile.ico"

    Case Else
      'this is a generic icon
      iconToUse = "C:\Windows\system32\packager.dll"
  End Select

  ActiveSheet.OLEObjects.Add(Filename:=fullFileName, Link:=False, DisplayAsIcon:=True, IconFileName:=iconToUse, IconIndex:=0, IconLabel:=fullFileName).Select3

End Sub


Private Sub CommandButton1_Click()

InsertObjectAsIcon

End Sub

Upvotes: 0

Views: 7196

Answers (1)

Skip Intro
Skip Intro

Reputation: 860

This code opens the common file dialog, filtered to show .xslx files. It picks up the path to the file, then inserts it into the activecell. There's also an inputbox asking for a short text name, if you don't want to see the full path.

Sub FileToLink()

Dim strFileName As String
Dim strShortName As String

strFileName = Application.GetOpenFilename("Excel Documents (*.xlsx), *.xlsx")

If strFileName = "False" Then
    Exit Sub ' user cancelled
End If

strShortName = InputBox("What do you want to call this link?", "Short Text", strFileName)

ActiveSheet.Hyperlinks.Add Anchor:=Selection, Address:=strFileName, TextToDisplay:=strShortName

End Sub

You can substitute strFileName = Application.GetOpenFilename("All Documents (*.*), *.*") to show all files. It doesn't matter to the link what file it is, as clicking on the link will invoke the application linked with that file type.

Upvotes: 3

Related Questions