CODEWITHSUNDEEP
sql-serversql-server-2008t-sql
Dev Issues
Dev Issues

Reputation: 23

Adding specific columns automatically while creating a new table

I am creating new database and in each table I want to have few columns like:

CreatedBy, 
CreatedDate, 
ModifiedBy, 
ModifiedDate,
....

So if anyone create table; these columns should add automatically and no need to script these columns in create table T-SQL. Either I create via design from Management Studio or use script it should add these columns automatically.

Is there any way to do this?

Upvotes: 1

Views: 1290

Answers (1)

Devart
Devart

Reputation: 122032

Try this dynamic query (automatically add columns to your tables):

DECLARE @SQL NVARCHAR(MAX)
SELECT @SQL = STUFF((
    SELECT CHAR(13) + 'ALTER TABLE [' + SCHEMA_NAME(o.[schema_id]) + '].[' + o.name + ']
    ADD 
          CreatedBy DATETIME
        , CreatedDate DATETIME
        , ModifiedBy DATETIME
        , ModifiedDate DATETIME;'
    FROM sys.objects o
    WHERE o.[type] = 'U'
        AND NOT EXISTS(
            SELECT 1 
            FROM sys.columns c
            WHERE o.[object_id] = c.[object_id]
                AND TYPE_NAME(c.system_type_id) = 'DATETIME'
                AND c.name IN ('CreatedBy', 'CreatedDate', 'ModifiedBy', 'ModifiedDate')
        )
    FOR XML PATH(''), TYPE).value('.', 'VARCHAR(MAX)'), 1, 1, '')


PRINT @SQL
EXEC sys.sp_executesql @SQL

Output:

ALTER TABLE [dbo].[test]
    ADD 
          CreatedBy DATETIME
        , CreatedDate DATETIME
        , ModifiedBy DATETIME
        , ModifiedDate DATETIME;

Update with DDL trigger:

CREATE TRIGGER TRG_TABLES
    ON DATABASE 
    AFTER CREATE_TABLE
AS 
BEGIN
    SET NOCOUNT ON;

    DECLARE @TABLE_NAME SYSNAME
    SELECT @TABLE_NAME = EVENTDATA().value('(/EVENT_INSTANCE/ObjectName)[1]', 'SYSNAME')

    DECLARE @SQL NVARCHAR(MAX)
    SELECT @SQL = STUFF((
        SELECT CHAR(13) + 'ALTER TABLE [' + SCHEMA_NAME(o.[schema_id]) + '].[' + o.name + ']
        ADD 
              CreatedBy DATETIME
            , CreatedDate DATETIME
            , ModifiedBy DATETIME
            , ModifiedDate DATETIME;'
        FROM sys.objects o
        WHERE o.[type] = 'U'
            AND o.[object_id] = OBJECT_ID(@TABLE_NAME)
            AND NOT EXISTS(
                SELECT 1 
                FROM sys.columns c
                WHERE o.[object_id] = c.[object_id]
                    AND TYPE_NAME(c.system_type_id) = 'DATETIME'
                    AND c.name IN ('CreatedBy', 'CreatedDate', 'ModifiedBy', 'ModifiedDate')
            )
        FOR XML PATH(''), TYPE).value('.', 'VARCHAR(MAX)'), 1, 1, '')

    EXEC sys.sp_executesql @SQL

END
GO

Save new table in SSMS or any another similar product. After it just reopen your table -

ttt

Upvotes: 3

Related Questions