CODEWITHSUNDEEP
perlsorting
MikeL
MikeL

Reputation: 2469

Sorting lines according to the numerical value of the first element on each line?

I have just started learning Perl, hence my question might seem very silly. I apologize in advance.

I have a list say @data which contains a list of lines read from the input. The lines contain numbers that are separated by (unknown number of) spaces.

Now, I would like to sort them and print them out, but not in the lexicographical order but according to the numerical value of the first number appearing on the line.

I know this must be something very simple but I cannot figure out how to do it?

Thanks in advance,

Upvotes: 0

Views: 241

Answers (2)

TLP
TLP

Reputation: 67900

You can use a Schwartzian transform, capturing the first number in the row with a regex

use strict;
use warnings;

my @sorted =    map $_->[0],
                sort { $a->[1] <=> $b->[1] }
                map { [ $_, /^(-?[\d.]+)/ ] } <DATA>;
print @sorted;

__DATA__
21  13  14
0   1   2
32  0   4
11  2   3
1   3   3

Output:

0       1       2
1       3       3
11      2       3
21      13      14
32      0       4

Reading the transform from behind, the <DATA> is the file handle we use, it will return a list of the lines in the file. The first map statement returns an array reference [ ... ], that contains the original line, plus the first number that is captured in the line. Alternatively, you can use the regex /^(\S+)/ here, to just capture whatever non-whitespace that comes first. The sort uses this captured number inside the array ref when comparing lines. And finally, the last map converts the array ref back to the original value, stored in $_->[0].

Be aware that this relies on the lines having a number at the start of the line. If that can be missing, or blank, this will have some unforeseen consequences.

Note that only using a simple numerical sort will also "work", because Perl will convert one of your lines to the correct number, assuming each line begins with a number followed by space. You will have some warnings about that, such as Argument "21 13 14\n" isn't numeric in sort. For example, if I replace my code above with

my @foo = sort { $a <=> $b } <DATA>;

I will get the output:

Argument "21    13      14\n" isn't numeric in sort at foo.pl line 6, <DATA> line 5.
Argument "0     1       2\n" isn't numeric in sort at foo.pl line 6, <DATA> line 5.
Argument "32    0       4\n" isn't numeric in sort at foo.pl line 6, <DATA> line 5.
Argument "11    2       3\n" isn't numeric in sort at foo.pl line 6, <DATA> line 5.
Argument "1     3       3\n" isn't numeric in sort at foo.pl line 6, <DATA> line 5.
0       1       2
1       3       3
11      2       3
21      13      14
32      0       4

But as you can see, it has sorted correctly. I would not advice this solution, but it is a nice demonstration in this context, I think.

Upvotes: 6

Jonysuise
Jonysuise

Reputation: 1840

You can use the sort function : 

@sorted_data = sort(@data);

Upvotes: -1

Related Questions