CODEWITHSUNDEEP
windowsvariablesbatch-filefor-loop
MangO_O
MangO_O

Reputation: 423

Correct syntax for variable modifiers when using EnableDelayedExpansion

I want to be able to do %~p to only see the path of the file. But I cant get the correct syntax when using it in a loop (With EnableDelayedExpansion)

Here's my code:

@echo off
set "dir1=%TMP%\opt"
set "dir2=c:\opt"
set "empty="

setlocal EnableDelayedExpansion
for /f %%F in ('dir  /a:-d /s /b /r "%dir1%"') do (
  set "file_path=%%F"
  set "file_name=%%~nF"
  set "new_path=!file_path:%dir1%=%dir2%!"
  set "new_path=!new_path:!file_name!=%empty%" //This command is problematic
  echo !new_path!
)
endlocal

Any way for me to do this?

Upvotes: 3

Views: 2699

Answers (1)

David Ruhmann
David Ruhmann

Reputation: 11367

Here is how to get and replace just the file path.

@echo off
setlocal EnableDelayedExpansion

set "dir1=%TMP%\opt"
set "dir2=c:\opt"

pushd "%dir1%" && for /f %%F in ('dir /a:-d /b /r /s') do (
    set "file_path=%%~dpF"
    set "new_path=!file_path:%dir1%=%dir2%!"
    echo !new_path!
) & popd

endlocal
exit /b 0

Explanation

The main change is the use of the ~dp modifiers for the variable which causes it to just get the full file path without the file name.

Your usage of the dir1 replacement was correct, it was your file name replacement that was bad. By using the ~dp modifier we can skip the file name replacement part completely.

The pushd is only called once before the for loop begins to set the working directory.

Walkthrough:

  • Set the working directory to dir1
  • Loop through all the files in that directory and subdirectories.
  • For each file get just the file path C:\Path\opt\sub not C:\path\opt\sub\file.ext
  • Replace the C:\path\opt with C:\opt
  • Display the result.
  • popd will restore the working directory to what it was before the pushd.

Here is a list of all the variable modifiers from the for /? help text.

In addition, substitution of FOR variable references has been enhanced.
You can now use the following optional syntax:

%~I         - expands %I removing any surrounding quotes (")
%~fI        - expands %I to a fully qualified path name
%~dI        - expands %I to a drive letter only
%~pI        - expands %I to a path only
%~nI        - expands %I to a file name only
%~xI        - expands %I to a file extension only
%~sI        - expanded path contains short names only
%~aI        - expands %I to file attributes of file
%~tI        - expands %I to date/time of file
%~zI        - expands %I to size of file
%~$PATH:I   - searches the directories listed in the PATH
               environment variable and expands %I to the
               fully qualified name of the first one found.
               If the environment variable name is not
               defined or the file is not found by the
               search, then this modifier expands to the
               empty string

The modifiers can be combined to get compound results:

%~dpI       - expands %I to a drive letter and path only
%~nxI       - expands %I to a file name and extension only
%~fsI       - expands %I to a full path name with short names only
%~dp$PATH:I - searches the directories listed in the PATH
               environment variable for %I and expands to the
               drive letter and path of the first one found.
%~ftzaI     - expands %I to a DIR like output line

In the above examples %I and PATH can be replaced by other valid
values.  The %~ syntax is terminated by a valid FOR variable name.
Picking upper case variable names like %I makes it more readable and
avoids confusion with the modifiers, which are not case sensitive.

Upvotes: 2

Related Questions