Reputation: 639

Mocking domain object is not working

I'm a grails/groovy newbie so please forgive me for this simple problem but I have really tried everything and I haven't succeded. In general I want to write really simple unit test for my service method. But I cannot figure out why my mock doesn't have a list.

My service:

class MenuService {

def mailService

def prepareMenu() {
    def newDinners = []
    def soups = Dish.findAllWhere(dishKind: DishKind.SOUP)
    def mainCourses = Dish.findAllWhere(dishKind: DishKind.MAIN_COURSE)
    def salads = Dish.findAllWhere(dishKind: DishKind.SALAD)
    def menu = checkIfMenuExists(Menu.last())

    deleteUsedMainCoursesAndSoups(menu, soups, mainCourses)
    deleteUsedSalads(menu, salads)

    Collections.shuffle(mainCourses)
    mainCourses = mainCourses.subList(0, 7);

    mainCourses.each {
        Dinner dinner = new Dinner()
        dinner.mainCourse = it
        if (it.withSoup) {
            Collections.shuffle(soups)
            dinner.soup = soups.get(0)
            soups.remove(0)
        }
        newDinners.add(dinner)
    }

    Collections.shuffle(salads)
    salads = salads.subList(0, 2)

    menu.dinners = newDinners
    menu.salads = salads

    menu.save()
    sendMenu(menu)
}

private void deleteUsedSalads(Menu menu, salads) {
    if (!menu.salads.isEmpty()) {
        menu.salads.each {
            if (salads.contains(it)) {
                salads.remove(it)
            }
        }
    }
}

private void deleteUsedMainCoursesAndSoups(Menu menu, soups, mainCourses) {
    if (!menu.dinners.isEmpty()) {
        menu.dinners.each {
            if (mainCourses.contains(it.mainCourse)) {
                mainCourses.remove(it)
            } else if (soups.contains(it.soup))
                soups.remove(it)
        }
    }
}

private Menu checkIfMenuExists(Menu menu) {
    if (menu == null) {
        menu = new Menu()
        menu.dinners = new ArrayList<Dinner>()
        menu.salads = new ArrayList<Dish>()
    }
    menu
}

def sendMenu(Menu menu) {
    mailService.sendMail {
        to ""
        subject ""
        body(view: "/mail", model: [dinners: menu.dinners, salads: menu.salads])
    }
}

}

and I have a test for it:

@TestFor(MenuService)
@Mock([Dish, Menu])
@TestMixin(DomainClassUnitTestMixin)
class MenuServiceTests {
def menuService = new MenuService()

void testIfItChoosesNewMenu() {

    def soups = [
            new Dish(name: "Soup 1", dishKind: DishKind.SOUP, ingredients: ""),
            new Dish(name: "Soup 2", dishKind: DishKind.SOUP, ingredients: ""),
            new Dish(name: "Soup 3", dishKind: DishKind.SOUP, ingredients: ""),
            new Dish(name: "Soup 4", dishKind: DishKind.SOUP, ingredients: ""),
            new Dish(name: "Soup 5", dishKind: DishKind.SOUP, ingredients: ""),
            new Dish(name: "Soup 6", dishKind: DishKind.SOUP, ingredients: ""),
            new Dish(name: "Soup 7", dishKind: DishKind.SOUP, ingredients: "")
    ]
    def mainCourses = [
            new Dish(name: "Main course 1", dishKind: DishKind.MAIN_COURSE, ingredients: ""),
            new Dish(name: "Main course 2", dishKind: DishKind.MAIN_COURSE, ingredients: ""),
            new Dish(name: "Main course 3", dishKind: DishKind.MAIN_COURSE, ingredients: ""),
            new Dish(name: "Main course 4", dishKind: DishKind.MAIN_COURSE, ingredients: ""),
            new Dish(name: "Main course 5", dishKind: DishKind.MAIN_COURSE, ingredients: ""),
            new Dish(name: "Main course 6", dishKind: DishKind.MAIN_COURSE, ingredients: ""),
            new Dish(name: "Main course 7", dishKind: DishKind.MAIN_COURSE, ingredients: ""),
            new Dish(name: "Main course 8", dishKind: DishKind.MAIN_COURSE, ingredients: ""),
            new Dish(name: "Main course 9", dishKind: DishKind.MAIN_COURSE, ingredients: ""),
            new Dish(name: "Main course 10", dishKind: DishKind.MAIN_COURSE, ingredients: ""),
            new Dish(name: "Main course 11", dishKind: DishKind.MAIN_COURSE, ingredients: ""),
            new Dish(name: "Main course 12", dishKind: DishKind.MAIN_COURSE, ingredients: ""),
            new Dish(name: "Main course 13", dishKind: DishKind.MAIN_COURSE, ingredients: ""),
            new Dish(name: "Main course 14", dishKind: DishKind.MAIN_COURSE, ingredients: "")
    ]
    def salads = [
            new Dish(name: "Salad 1", dishKind: DishKind.SALAD, ingredients: ""),
            new Dish(name: "Salad 2", dishKind: DishKind.SALAD, ingredients: ""),
            new Dish(name: "Salad 3", dishKind: DishKind.SALAD, ingredients: ""),
            new Dish(name: "Salad 4", dishKind: DishKind.SALAD, ingredients: ""),
    ]

    mockDomain(Dish, [soups, mainCourses, salads])
    Menu menu = menuService.prepareMenu()

    assertEquals 2, menu.salads.size()
    assertEquals 7, menu.dinners.size()
}

}

When I run test I have a fail:

Failure:  testIfItChoosesNewMenu(familyhelper.MenuServiceTests)
java.lang.IndexOutOfBoundsException: toIndex = 7
at java.util.SubList.<init>(AbstractList.java:602)
at java.util.RandomAccessSubList.<init>(AbstractList.java:758)
at java.util.AbstractList.subList(AbstractList.java:468)
at familyhelper.MenuService.prepareMenu(MenuService.groovy:18)
at familyhelper.MenuServiceTests.testIfItChoosesNewMenu(MenuServiceTests.groovy:51)

because:

    def soups = Dish.findAllWhere(dishKind: DishKind.SOUP)
    def mainCourses = Dish.findAllWhere(dishKind: DishKind.MAIN_COURSE)
    def salads = Dish.findAllWhere(dishKind: DishKind.SALAD)

are empty. I have read that all dynamic functions for domain objects are injected when I add @Mock annotation but even that does not help me. Does anybody know how to fix this test? Thanks in advance

Upvotes: 0

Answers (3)

rxn1d

Reputation: 1266

To find something in DB with GORM you need to save it first. @Alidad was right, but you should probably use:

 new Dish(...).save(false)

false in save disables your domain entity validation.

Upvotes: 1

dmahapatro

Reputation: 50245

You do not need to explicitly mock the domain class. @Mock should do that for you.

@TestFor(MenuService)
@Mock([Dish, Menu])
class MenuServiceTests {

    void testIfItChoosesNewMenu() {

        def soups = [
            new Dish(name: "Soup 1", dishKind: DishKind.SOUP, ingredients: ""),
            new Dish(name: "Soup 2", dishKind: DishKind.SOUP, ingredients: ""),
            new Dish(name: "Soup 3", dishKind: DishKind.SOUP, ingredients: ""),
            new Dish(name: "Soup 4", dishKind: DishKind.SOUP, ingredients: ""),
            new Dish(name: "Soup 5", dishKind: DishKind.SOUP, ingredients: ""),
            new Dish(name: "Soup 6", dishKind: DishKind.SOUP, ingredients: ""),
            new Dish(name: "Soup 7", dishKind: DishKind.SOUP, ingredients: "")
        ]

        def mainCourses = [
            new Dish(name: "Main course 1", dishKind: DishKind.MAIN_COURSE, ingredients: ""),
            new Dish(name: "Main course 2", dishKind: DishKind.MAIN_COURSE, ingredients: ""),
            new Dish(name: "Main course 3", dishKind: DishKind.MAIN_COURSE, ingredients: ""),
            new Dish(name: "Main course 4", dishKind: DishKind.MAIN_COURSE, ingredients: ""),
            new Dish(name: "Main course 5", dishKind: DishKind.MAIN_COURSE, ingredients: ""),
            new Dish(name: "Main course 6", dishKind: DishKind.MAIN_COURSE, ingredients: ""),
            new Dish(name: "Main course 7", dishKind: DishKind.MAIN_COURSE, ingredients: ""),
            new Dish(name: "Main course 8", dishKind: DishKind.MAIN_COURSE, ingredients: ""),
            new Dish(name: "Main course 9", dishKind: DishKind.MAIN_COURSE, ingredients: ""),
            new Dish(name: "Main course 10", dishKind: DishKind.MAIN_COURSE, ingredients: ""),
            new Dish(name: "Main course 11", dishKind: DishKind.MAIN_COURSE, ingredients: ""),
            new Dish(name: "Main course 12", dishKind: DishKind.MAIN_COURSE, ingredients: ""),
            new Dish(name: "Main course 13", dishKind: DishKind.MAIN_COURSE, ingredients: ""),
            new Dish(name: "Main course 14", dishKind: DishKind.MAIN_COURSE, ingredients: "")
        ]

        def salads = [
            new Dish(name: "Salad 1", dishKind: DishKind.SALAD, ingredients: ""),
            new Dish(name: "Salad 2", dishKind: DishKind.SALAD, ingredients: ""),
            new Dish(name: "Salad 3", dishKind: DishKind.SALAD, ingredients: ""),
            new Dish(name: "Salad 4", dishKind: DishKind.SALAD, ingredients: "")
        ]

        //Save the domain classes
        [soups, mainCourses, salads].each{it*.save(flush: true, failOnError: true)}

        //Note service is auto injected by @TestFor
        //SO no need to instantiate
        Menu menu = service.prepareMenu() 

        assertEquals 2, menu.salads.size()
        assertEquals 7, menu.dinners.size()
    }
}

If you are not already cognizant of build test data plugin then I would suggest to use it for these kind of tests. As a whole, I would also suggest to use spock as a test framework.

Upvotes: 2

Alidad

Reputation: 5538

Possibly you forgot to save the Dishes,

def salads = [
            new Dish(name: "Salad 1", dishKind: DishKind.SALAD, ingredients: "").save(),
            new Dish(name: "Salad 2", dishKind: DishKind.SALAD, ingredients: "").save(),
            new Dish(name: "Salad 3", dishKind: DishKind.SALAD, ingredients: "").save(),
            new Dish(name: "Salad 4", dishKind: DishKind.SALAD, ingredients: "").save(),
    ]

Upvotes: 1

Mocking domain object is not working

Answers (3)

Related Questions