CODEWITHSUNDEEP
actionscript-3airflash-builder
Ted
Ted

Reputation: 2585

Access asset / resource file in an ActionScript Library project

I'm using an ActionScript Library project to share code and assets / resources between a Mobile and a Desktop ActionScript projects.

The library project has been added to the two other projects via the 'Add Project' option on the 'Library Path' tab, with the linkage type 'Merged into Code', and all the classes within it can be accessed by the other projects, and work properly.

However it contains a SQLite database file, which I want to copy out to the File.applicationStorageDirectory on the target system on the first load of the app, and I'm not sure how to get a reference to the file within the library project to copy it out.

The location of the db file is: LibraryProj - src/database/dbFile.db and I thought using File.applicationDirectory and then a path 'into' the swf would give me access to it, but none of the following tests say the file exists.

var test:File;

test = File.applicationDirectory.resolvePath("app:/src/database/dbFileDb.db"); 
trace("test.exists==" + test.exists); 

test = File.applicationDirectory.resolvePath("src/database/dbFileDb.db"); 
trace("test.exists==" + test.exists);
test = File.applicationDirectory.resolvePath("database/dbFileDb.db"); 
trace("test.exists==" + test.exists); 
test = File.applicationDirectory.resolvePath("dbFileDb.db"); 
trace("test.exists==" + test.exists);

Is this the correct method to copy resource / asset files out of a swf containing merged libraries and onto the app's storage directory? Is it even possible to share resources / assets from Library projects in this way?

Any advice would be very much appreciated.

Upvotes: 0

Views: 437

Answers (1)

Ted
Ted

Reputation: 2585

After doing some more research about using the [Embed] tag in AS3, I've now worked out that this is what I should have been using to make the file available to consuming projects (I'd previously only used it for images, and didn't think of it for other file types too).

[Embed('igniteDb.db', mimeType="application/octet-stream")]
public static const myReferenceDbFile:Class;

To copy the file to the File.applicationStorageDirectory i'm using the following code. It converts the embedded file to a byte array, and then writes this out via a FileStream class to the destination file.

//write the embedded database file data into app user files directory
var bundleDbBytes:ByteArray;
bundleDbBytes = new myReferenceDbFile();//gets a reference to the embedded db file

var outputDbFile:File = File.applicationStorageDirectory.resolvePath(DB_FILE_NAME);
var fileStream:FileStream = new FileStream();
fileStream.open(outputDbFile, FileMode.UPDATE);
fileStream.writeBytes(bundleDbBytes);
fileStream.close();

And hey presto, the database is ready to use.

Upvotes: 1

Related Questions