Buras
Buras

Reputation: 3099

How to have vba execute every 10 minutes?

I need to have my macro executed every 10 minutes .

This allows it to work in 10 minutes

sub my_Procedure () 
msgbox "hello world"
end sub

sub test()
Application.OnTime Now + TimeValue("00:00:10"), "my_Procedure"
end sub

But this works only once . How can I have my macro execute every 10 minutes ?

Upvotes: 14

Views: 111148

Answers (2)

Dmitry Pavliv
Dmitry Pavliv

Reputation: 35863

You should use this pattern:

Sub my_Procedure()
    MsgBox "hello world"        
    Call test ' for starting timer again
End Sub

Sub test()
    Application.OnTime Now + TimeValue("00:10:00"), "my_Procedure"
End Sub

Upvotes: 37

Gary's Student
Gary's Student

Reputation: 96791

Consider:

Public RunWhen As Double
Public Const cRunWhat = "my_Procedure"

Sub StartTimer()
RunWhen = Now + TimeSerial(0, 10, 0)
Application.OnTime earliesttime:=RunWhen, procedure:=cRunWhat, _
     schedule:=True
End Sub

Sub StopTimer()
   On Error Resume Next
   Application.OnTime earliesttime:=RunWhen, _
       procedure:=cRunWhat, schedule:=False
End Sub

Sub my_Procedure()
    MsgBox "hello world"
    Call StartTimer
End Sub

all in a standard module..............be sure to run StopTimer before exiting Excel

NOTE

The "minute" argument in TimeSerial is the second argument.

Upvotes: 15

Related Questions