CODEWITHSUNDEEP
puppet
kamal
kamal

Reputation: 9785

How can i install a local rpm using puppet

I am trying to install a particular rpm using puppet, my init.pp is:

class nmap {
  package {'nmap':
    provider => 'rpm',
    source => "<Local PATH to the RPM>",
  }
}

and the rpm is in ...modules/nmap/files

If i move the rpm to manifests, and provide the rpm name in source => ''

class nmap {
  package {'nmap':
    provider => 'rpm',
    source => "rpm-name.rpm",
  }
}

it works, but how can i specify source path with ../files/ and do puppet apply successfully

When i use :

source => 'puppet:///files/nmap-6.45-1.x86_64.rpm',

i get an error:

Debug: Executing '/bin/rpm -i puppet:///files/nmap-6.45-1.x86_64.rpm' Error: Execution of '/bin/rpm -i puppet:///files/nmap-6.45-1.x86_64.rpm' returned 1: error: open of puppet:///files/nmap-6.45-1.x86_64.rpm failed: No such file or directory

Error: /Stage[main]/Nmap/Package[nmap]/ensure: change from absent to present failed: Execution of '/bin/rpm -i puppet:///files/nmap-6.45-1.x86_64.rpm' returned 1: error: open of puppet:///files/nmap-6.45-1.x86_64.rpm failed: No such file or directory `

when running the command:

sudo puppet apply --modulepath=/home/user1/qa/puppet_qa/modules/ -e "include nmap" --debug

Upvotes: 16

Views: 40164

Answers (4)

Vadim Sluzky
Vadim Sluzky

Reputation: 259

The RPM package can be installed this way:

 package { 'epel-release-6':
   provider => 'rpm',
   ensure   => 'present',
   source   => '/usr/local/rpms/epel-release-latest-6.noarch.rpm',
 }

Upvotes: 4

Sourabh Wadhwa
Sourabh Wadhwa

Reputation: 1

Lets start from start :

on server:

$rpm -ivh https://yum.puppetlabs.com/puppetlabs-release-pc1-el-7.noarch.rpm
$yum -y install puppetserver
$vi /etc/sysconfig/puppetserver #change JAVA args
$systemctl start puppetserver
$systemctl enable puppetserver
$vi /etc/puppetlabs/puppet/puppet.conf #Add “dns_alt_names” in [master]

On Agent:

$rpm -ivh https://yum.puppetlabs.com/puppetlabs-release-pc1-el-7.noarch.rpm
$yum -y install puppet-agent
$systemctl start puppet
$systemctl enable puppet
$vi /etc/puppetlabs/puppet/puppet.conf # Add “server = pupmaster” in [main]


puppet cert list
puppet cert sign




/etc/puppetlabs/code/environments/production/manifests/site.pp:

node webserver {
  class { 'apache': }
}

node dbserver {
  class { ‘mysql’: }
}


mkdir –p /etc/puppetlabs/code/environments/production/modules/apache/{manifests, files}

apacheinstall.pp:

  class apache::apacheinstall {

    if $osfamily == 'redhat' {

            package { 'httpd':
                      ensure => 'latest'
                    }

            service {'httpd':
                       ensure => 'running',
                      require => Package["httpd"],
                    }

            file { '/var/www/html/ndex.html':
                    mode => "0644",
                    owner => 'root',
                    group => 'root',
                    source => 'puppet:///modules/apache/index.html',
                  }
    }
    elsif $osfamily == 'debian' {

            package { 'apache2':
                      ensure => 'latest'
                    }

            service {'httpd':
                      ensure => 'running',
                      require => Package["httpd"],
                    }
    }
  }

INIT.pp

  class apache {
    notify { 'Installing and Configuring Webserver for $osfamily': }
    include apache::mysqlinstall
  }

Mysqlinstall.pp:

  class apache::mysqlinstall {

            exec { 'wget':
            path      => [ "/bin/", "/sbin/", "/usr/bin/", "/usr/sbin/" ],
            command   => "/usr/bin/wget https://dev.mysql.com/get/mysql57-community-release-el7-9.noarch.rpm && rpm -ivh /tmp/mysql57-community-release-el7-9.noarch.rpm",
            cwd       => '/tmp/',
            creates   => '/etc/firstruns/p1.done',
            }
  }

Upvotes: 0

Felix Frank
Felix Frank

Reputation: 8223

Unlike the file resource type, the package type has no support for Puppet fileserver URLs. You will need to use a file resource to download the rpm prior to installing it. If this is a recurring problem for you, make a defined type that does those in one go (think macros), e.g.

define fileserver_package($source, $ensure='installed') {
  file { "/my/tmp/dir/$name.rpm": source => $source }
  package { $name:
    ensure => $ensure,
    provider => 'rpm',
    source => "/my/tmp/dir/$name.rpm",
    require => File["/my/tmp/dir/$name.rpm"],
  }
}

Edit: it is generally advisable to use a local yum repo instead, see also the first comment by @rojs below.

Upvotes: 18

iamauser
iamauser

Reputation: 11469

It seems the module name you are using is nmap. You can use the same source parameter like this,

source => 'puppet:///modules/nmap/nmap-6.45-1.x86_64.rpm',

The syntax to access a file under a module goes like this,

  puppet:///modules/<modulename>/<file you want to access>

See this link here, http://docs.puppetlabs.com/puppet/latest/reference/modules_fundamentals.html#files

Upvotes: 1

Related Questions