CODEWITHSUNDEEP
actionscript-3flashgame-physics
Ziggy
Ziggy

Reputation: 375

ActionScript 3 - hitTestObject error

At first, when I ran the movie, I thought hitTestObject was straight up not working. However, when I tinkered a little, I saw that the code only worked if the player( mcMain ) was touching the wall when the movie started running.

I want "yes" to trace every time the player touches the wall, but if the player is not touching the wall from the get-go, moving into it does nothing.

Someone please help.

Source code(hitTestObject method call is at the very bottom.)

//whether or not the main guy is jumping
var mainJumping:Boolean = false;
//how quickly should the jump start off
var jumpSpeedLimit:int = 15;
//the current speed of the jump;
var jumpSpeed:Number = jumpSpeedLimit;
//jumping function
function mainJump():void{
    //if main isn't already jumping
    if(!mainJumping){
        //then start jumping
        mainJumping = true;
        jumpSpeed = jumpSpeedLimit*-1;
        mcMain.y += jumpSpeed;
    } else {
        //then continue jumping if already in the air
        //crazy math that I won't explain
        if(jumpSpeed < 0){
            jumpSpeed *= 1 - jumpSpeedLimit/75;
            if(jumpSpeed > -jumpSpeedLimit/5){
                jumpSpeed *= -1;
            }
        }
        if(jumpSpeed > 0 && jumpSpeed <= jumpSpeedLimit){
            jumpSpeed *= 1 + jumpSpeedLimit/50;
        }
        mcMain.y += jumpSpeed;
        //if main hits the floor, then stop jumping
        //of course, we'll change this once we create the level
        if(mcMain.y >= stage.stageHeight - mcMain.height){
            mainJumping = false;
            mcMain.y = stage.stageHeight - mcMain.height;
        }
    }
}


//These variables will note which keys are down
//We don't need the up or down key just yet
//but we will later
var leftKeyDown:Boolean = false;
var upKeyDown:Boolean = false;
var rightKeyDown:Boolean = false;
var downKeyDown:Boolean = false;
//the main character's speed
var mainSpeed:Number = 7;

//adding a listener to mcMain which will make it move
//based on the key strokes that are down
mcMain.addEventListener(Event.ENTER_FRAME, moveChar);
function moveChar(event:Event):void{
    //if certain keys are down then move the character
    if(leftKeyDown){
        mcMain.x -= mainSpeed;
    }
    if(rightKeyDown){
        mcMain.x += mainSpeed;
    }
    if(upKeyDown || mainJumping){
        mainJump();
    }
}
//listening for the keystrokes
//this listener will listen for down keystrokes
stage.addEventListener(KeyboardEvent.KEY_DOWN, checkKeysDown);
function checkKeysDown(event:KeyboardEvent):void{
    //making the booleans true based on the keycode
    //WASD Keys or arrow keys
    if(event.keyCode == 65){
        leftKeyDown = true;
    }
    if(event.keyCode == 87){
        upKeyDown = true;
    }
    if(event.keyCode == 68){
        rightKeyDown = true;
    }
    if(event.keyCode == 83){
        downKeyDown = true;
    }
}
//this listener will listen for keys being released
stage.addEventListener(KeyboardEvent.KEY_UP, checkKeysUp);
function checkKeysUp(event:KeyboardEvent):void{
    //making the booleans false based on the keycode
    if(event.keyCode == 65){
        leftKeyDown = false;
    }
    if(event.keyCode == 87){
        upKeyDown = false;
    }
    if(event.keyCode == 68){
        rightKeyDown = false;
    }
    if(event.keyCode == 83){
        downKeyDown = false;
    }
}

if(mcMain.hitTestObject(wall1)){
    trace("yes");
}

Upvotes: 0

Views: 112

Answers (1)

Gigggas
Gigggas

Reputation: 315

In the code you posted, it looks like your hitTest code is not in any kind of function. It probably should be in a function that is checked every time the player moves. Like so:

function checkHitWall():void{
    if(mcMain.hitTestObject(wall1)){
        trace("yes");
    }
}
.....
function moveChar(event:Event):void{
    //if certain keys are down then move the character
    if(leftKeyDown){
        mcMain.x -= mainSpeed;
    }
    if(rightKeyDown){
        mcMain.x += mainSpeed;
    }
    if(upKeyDown || mainJumping){
        mainJump();
    }
    checkHitWall();
}

Upvotes: 1

Related Questions