Perl - Pack Complex 16-bit Word

Question

I have to pack a complicated message into a 16-bit word that is defined like so:

• Part 1: Error State (Least Significant Byte)
  • Bit 0: Error type A (Least Significant Bit)
  • Bit 1: Error type B
  • Bit 2: Error type C
  • Bit 3: Error type D
  • Bit 4: Error type E
  • Bit 5: Error type F
  • Bit 6: Error type G
  • Bit 7: Error type H (Most significant Bit)
• Part 2: Mode/Status Additional Status is defined like so:
  • Mode: The mode is contained in the least significant 4 bits of the most significant byte. Mode numbers go 0 - 11.
  • Bit 12: Status Type A
  • Bit 13: Status Type B
  • Bit 14: Status Type C
• Additional Status:
  • Bit 15: Reset on/off

I can't seem to get the pack() command right. I want to pack: Error type E, Mode 7, Status Type B, Additional Status ON

my $msg = pack("n",
    pack("C", 0, 0, 0, 0, 1, 0, 0, 0), #error state
    pack("C", 7, 0, 1, 0, 1)
);

Perl doc, http://perldoc.perl.org/functions/pack.html, does not say about little/big endian when it comes to packing chars.

Answer 1

pack produces 1 or more byte for each input, so it can't accept bits. Build your word first, then pass it to pack.

my $word = 0;

$word |= 1 << 0 if $error_type_A;
$word |= 1 << 1 if $error_type_B;
$word |= 1 << 2 if $error_type_C;
$word |= 1 << 3 if $error_type_D;
$word |= 1 << 4 if $error_type_E;
$word |= 1 << 5 if $error_type_F;
$word |= 1 << 6 if $error_type_G;
$word |= 1 << 7 if $error_type_H;

$word |= $mode << 8;

$word |= 1 << 12 if $status_type_A;
$word |= 1 << 13 if $status_type_B;
$word |= 1 << 14 if $status_type_C;

$word |= 1 << 15 if $reset;

pack 'n', $word

Answer 2

You could try using vec instead of pack. Eg:

vec($i, 0,1) = 1;               # set bit zero
print unpack('b*', $i), "\n";   # 10000000
vec($i, 1,1) = 1;               # set bit 1 
print unpack('b*', $i), "\n";   # 11000000
vec($i, 4,1) = 1;               # set bit 4
print unpack('b*', $i), "\n";   # 11001000
vec($i, 15,1) = 1;              # set bit 15
print unpack('b*', $i), "\n";   # 1100100000000001