CODEWITHSUNDEEP
vb.netprocess
Oman Dot Kom
Oman Dot Kom

Reputation: 3

Detect when selected process has exited

How to detect when the selected process is closed in vb.net ? i tried all codes in google, but it still fails.

here's the code : 

Private Sub Process1_Exited(ByVal sender As System.Object,
                            ByVal e As System.EventArgs) Handles Process1.Exited
  MessageBox.Show("exited")
End Sub

but when the process is closed, there's nothing appear.

Upvotes: 0

Views: 1301

Answers (2)

user3453226
user3453226

Reputation:

Process1_Exited is an event handler - you have to register it. You may want to work with Process class. See Process.Exited.

Dim Process1 As New Process ' Getting a new object
Process1.StartInfo.FileName = "" ' Setting up the file path
Process1.EnableRaisingEvents = True ' Enabling raising events
AddHandler Process1.Exited, AddressOf Process1_Exited ' Registering your event handler
Process1.Start() ' Starting the process

Private Sub Process1_Exited(ByVal sender As Object, ByVal e As System.EventArgs)
    ' Process exited
End Sub

Upvotes: 2

Capt Mayhem
Capt Mayhem

Reputation: 41

Add these Win32 declarations

   Private Type STARTUPINFO
      cb As Long
      lpReserved As String
      lpDesktop As String
      lpTitle As String
      dwX As Long
      dwY As Long
      dwXSize As Long
      dwYSize As Long
      dwXCountChars As Long
      dwYCountChars As Long
      dwFillAttribute As Long
      dwFlags As Long
      wShowWindow As Integer
      cbReserved2 As Integer
      lpReserved2 As Long
      hStdInput As Long
      hStdOutput As Long
      hStdError As Long
   End Type

   Private Type PROCESS_INFORMATION
      hProcess As Long
      hThread As Long
      dwProcessID As Long
      dwThreadID As Long
   End Type

   Private Declare Function WaitForSingleObject Lib "kernel32" (ByVal _
      hHandle As Long, ByVal dwMilliseconds As Long) As Long

   Private Declare Function CreateProcessA Lib "kernel32" (ByVal _
      lpApplicationName As String, ByVal lpCommandLine As String, ByVal _
      lpProcessAttributes As Long, ByVal lpThreadAttributes As Long, _
      ByVal bInheritHandles As Long, ByVal dwCreationFlags As Long, _
      ByVal lpEnvironment As Long, ByVal lpCurrentDirectory As String, _
      lpStartupInfo As STARTUPINFO, lpProcessInformation As _
      PROCESS_INFORMATION) As Long

   Private Declare Function CloseHandle Lib "kernel32" _
      (ByVal hObject As Long) As Long

   Private Declare Function GetExitCodeProcess Lib "kernel32" _
      (ByVal hProcess As Long, lpExitCode As Long) As Long

   Private Const NORMAL_PRIORITY_CLASS = &H20&
   Private Const INFINITE = -1&

   Public Function ExecCmd(cmdline$)
      Dim proc As PROCESS_INFORMATION
      Dim start As STARTUPINFO

      ' Initialize the STARTUPINFO structure:
      start.cb = Len(start)

      ' Start the shelled application:
      ret& = CreateProcessA(vbNullString, cmdline$, 0&, 0&, 1&, _
         NORMAL_PRIORITY_CLASS, 0&, vbNullString, start, proc)

      ' Wait for the shelled application to finish:
         ret& = WaitForSingleObject(proc.hProcess, INFINITE)
         Call GetExitCodeProcess(proc.hProcess, ret&)
         Call CloseHandle(proc.hThread)
         Call CloseHandle(proc.hProcess)
         ExecCmd = ret&
   End Function

   Sub Your_Sub_To_Wait_For_Exit()
      Dim retval As Long
      retval = ExecCmd("notepad.exe")
      MsgBox "Process Finished, Exit Code " & retval
   End Sub

The MsgBox statement following the ExecCmd() function is not executed because the WaitForSingleObject() function prevents it. The message box does not appear until Notepad is closed when the user chooses Exit from Notepad's File menu (ALT, F, X)

Upvotes: 0

Related Questions