CODEWITHSUNDEEP
delphivcl
Johan
Johan

Reputation: 76567

How do draw a rotated roundrect

It's easy to draw a RoundRect:

procedure RoundRect(X1, Y1, X2, Y2, X3, Y3: Integer); override;

It's also easy to draw a rotated rectangle.

Get the corner points and rotate them like so:

procedure RotatePoints(var Points: TArray<TPoint>; const Angle: Double; const OrgPt: TPoint);
var
  Sin, Cos: Double;
  Prime: TPoint;
  P: TPoint;
begin
 SinCos(NormalizeAngle(Angle), Sin, Cos);
 for P in Points do begin
   Prime.X := P.X - OrgPt.X;
   Prime.Y := P.Y - OrgPt.Y;
   P.X := Round(Prime.X * Cos - Prime.Y * Sin) + OrgPt.X;
   P.Y := Round(Prime.X * Sin + Prime.Y * Cos) + OrgPt.Y;
end;

But how do I draw a rotated RoundRect?
Note that I'm using the VCL and not Firemonkey.

Upvotes: 2

Views: 754

Answers (1)

Sertac Akyuz
Sertac Akyuz

Reputation: 54812

You can use SetWorldTransform to have rotation on the device context you intend to use. Example:

procedure RotatedRoundRect(DC: HDC; Degrees: Integer;
    X1, Y1, X2, Y2, X3, Y3: Integer);
var
  XForm, SaveXForm: TXForm;
  r: Single;
  ht, vt: Single;
  SaveMode: Integer;
begin
  r := (2 * pi * Degrees) / 360;

  XForm.eM11 := Cos(r);
  XForm.eM12 := Sin(r);
  XForm.eM21 := - XForm.eM12;
  XForm.eM22 := XForm.eM11;
  ht := (X1 + X2) / 2;
  vt := (Y1 + Y2) / 2;
  XForm.eDx := ht - XForm.eM11 * ht + XForm.eM12 * vt;
  XForm.eDy := vt - XForm.eM11 * vt - XForm.eM12 * ht;

  GetWorldTransform(DC, SaveXForm);
  SaveMode := GetGraphicsMode(DC);
  SetGraphicsMode(DC, GM_ADVANCED);
  SetWorldTransform(DC, XForm);
  RoundRect(DC, X1, Y1, X2, Y2, X3, Y3);
  SetWorldTransform(DC, SaveXForm);
  SetGraphicsMode(DC, SaveMode);
end;

Sample call for a 15° clockwise rotated rounded rectangle:

RotatedRoundRect(Canvas.Handle, 15, 30, 20, 210, 150, 25, 25);

Upvotes: 7

Related Questions