Motorola Handheld MC55A Development

Question

i have Motorola Handheld MC55A with windows embedded handheld 6.5 and i want to start develop an app to read barcode .I didn't find any reference to do my command i have installed VS2008 and start to create Smart Device Application with a simple form

Answer 1

Merit who deserve merit: Initially I didn't write the following code, I'm not sure who initially did it, may be was written by symbol developers...I'm not sure, I only have used it.

1- First at all download and install the Motorola EMDK, after that, you will copy the C:\Program Files (x86)\Motorola EMDK for .NET\v2.5\SDK\Smart Devices\Symbol.Barcode.dll file to \My Device\Windows folder in your pocket.

Public Class frmTest
Dim MyReader As Symbol.Barcode.Reader = Nothing
Dim MyReaderData As Symbol.Barcode.ReaderData = Nothing
Dim MyEventHandler As System.EventHandler = Nothing
Dim MyHandlerCB As System.EventHandler = Nothing

Private Sub frmTest_Load(ByVal sender As Object, ByVal e As System.EventArgs) Handles MyBase.Load
    InitReader()
End Sub

Protected Overloads Overrides Sub OnClosing(ByVal e As System.ComponentModel.CancelEventArgs)
    StopRead()
    Me.TermReader()
    MyBase.OnClosing(e)
End Sub

Private Function InitReader() As Boolean
    ' If reader is already present then fail initialize
    If Not (Me.MyReader Is Nothing) Then
        Return False
    End If
    'Create new reader, first available reader will be used.
    Me.MyReader = New Symbol.Barcode.Reader
    'Create reader data
    Me.MyReaderData = New Symbol.Barcode.ReaderData( _
                                 Symbol.Barcode.ReaderDataTypes.Text, _
                                 Symbol.Barcode.ReaderDataLengths.DefaultText)
    ' create event handler delegate
    Me.MyEventHandler = New System.EventHandler(AddressOf MyReader_ReadNotify)
    'Enable reader, with wait cursor
    Me.MyReader.Actions.Enable()
    Return True
End Function

Private Sub TermReader()
    'If we have a reader
    If Not (Me.MyReader Is Nothing) Then
        'Disable reader, with wait cursor
        Me.MyReader.Actions.Disable()
        'free it up
        Me.MyReader.Dispose()
        ' Indicate we no longer have one
        Me.MyReader = Nothing
    End If
    ' If we have a reader data
    If Not (Me.MyReaderData Is Nothing) Then
        'Free it up
        Me.MyReaderData.Dispose()
        'Indicate we no longer have one
        Me.MyReaderData = Nothing
    End If
End Sub

Private Sub StartRead()
    'If we have both a reader and a reader data
    If Not ((Me.MyReader Is Nothing) And (Me.MyReaderData Is Nothing)) Then
        'Submit a read
        AddHandler MyReader.ReadNotify, Me.MyEventHandler
        Me.MyReader.Actions.Read(Me.MyReaderData)
    End If
End Sub

Private Sub StopRead()
    'If we have a reader
    If Not (Me.MyReader Is Nothing) Then
        'Flush (Cancel all pending reads)
        RemoveHandler MyReader.ReadNotify, Me.MyEventHandler
        Me.MyReader.Actions.Flush()
    End If
End Sub

Private Sub MyReader_ReadNotify(ByVal o As Object, ByVal e As EventArgs)
    Dim TheReaderData As Symbol.Barcode.ReaderData = Me.MyReader.GetNextReaderData()
    'If it is a successful read (as opposed to a failed one)
    If (TheReaderData.Result = Symbol.Results.SUCCESS) Then
        'Handle the data from this read
        Me.HandleData(TheReaderData)
        'Start the next read
        Me.StartRead()
    End If
End Sub

Private Sub HandleData(ByVal TheReaderData As Symbol.Barcode.ReaderData)
    txtBarCode.Text = TheReaderData.Text
End Sub

Private Sub txtBarCode_GotFocus(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles txtBarCode.GotFocus
    StartRead()
End Sub

Private Sub txtBarCode_LostFocus(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles txtBarCode.LostFocus
    StopRead()
End Sub

End Class

Answer 2

You want to scan barcodes and insert them into textboxes from your app? Try to enable Data Wedge from Control Panel.