CODEWITHSUNDEEP
graphstata
MERose
MERose

Reputation: 4431

Remove legend from combined bar graph by categorical variables

I am trying to combine two bar graphs using graph combine. Both graphs have the same legend so I want one legend to disappear.

But since the bar graphs themselves are a kind of combined graph, legend(off) won't work.

Here is how the two graphs are generated:

graph bar (mean)over_econ over_lab over_cul over_coh over_fut, ytitle(Frequency) xsize(6.5) by(respondent)

graph bar (mean)over_econ over_lab over_cul over_coh over_fut, ytitle(Frequency) xsize(6.5) by(city_problem)

where respondent and city_problem refer to categorical variables. The legends are automatically produced by Stata.

Any suggestions how to remove the legend in either case?

Upvotes: 0

Views: 7213

Answers (2)

MERose
MERose

Reputation: 4431

As soon as I started to think about what by() does, I found the answer myself. One has to toggle off the legend via legend(off) within by():

graph bar (mean)over_econ over_lab over_cul over_coh over_fut, ytitle(Frequency) xsize(6.5) by(respondent, legend(off))

Upvotes: 1

Rachel Gallen
Rachel Gallen

Reputation: 28593

grc1leg is made for when you want one legend for combined graphs.

Install it first 

net install grc1leg,from( http://www.stata.com/users/vwiggins/)

enter image description here

code sample:

net install grc1leg,from( http://www.stata.com/users/vwiggins/)

clear   all


input quest str25 q      a1 a2 a3 a4 a5 a6
1 "Question 1"           0  2  37 45 12 4
1 "Benchmark Q1"         2  5  25 47 17 4
2 "Question 2"           1  37  2 40 17 3
2 "Benchmark Q2"         2  5  25 47  4 17
3 "Question 3"           1  2  40 37 17 3
3 "Benchmark Q3"         2  5  25 47 17 4
4 "Question 4"           1  2  37  17 3 40
4 "Benchmark Q4"         2  5  47 25 17 4
end 

graph hbar a1-a6 if quest==1, percent over(quest, gap(1)) over(q, gap(10))   ///
stack legend(off) yscale(off) yline(20 40 60 80 ,lwidth(0.25) lcolor(black)) ///
saving(a1, replace)yscale(off) plotregion(margin( b+3 t+3))  outergap(30)

graph hbar a1-a6 if quest==2, percent over(quest, gap(1)) over(q, gap(10))   ///
stack legend(off) yscale(off) yline(20 40 60 80 ,lwidth(0.25)lcolor(black))  ///
saving(a1a, replace)yscale(off) plotregion(margin( b+3 t+3))  outergap(30)

graph hbar a1-a6 if quest==3, percent over(quest, gap(1)) over(q, gap(10))    ///
stack legend(off) yscale(off) yline(20 40 60 80 ,lwidth(0.25)  lcolor(black)) ///
saving(a1b, replace)yscale(off) plotregion(margin( b+3 t+3))  outergap(30)


graph hbar a1-a6 if quest==4, percent over(quest, gap(1)) over(q, gap(20))    ///
stack legend(span rows(1) label(1 "Missing") label(2 "Never")                 ///
label(3 "Rarely") label(4 "Occasionly  ") label(5 "Mostly")                   ///
label(6 "Always    ") size(small))                                            ///
yline(20 40 60 80 ,lwidth(0.25 ) lcolor(black)) saving(a2, replace)


grc1leg a1.gph a1a.gph a1b.gph a2.gph, cols(1) ///
imargin(0 0 0 0) ycommon xcommon legendfrom(a2.gph)

exit

See the example at http://www.survey-design.com.au/Stata%20Graphs.html

Upvotes: 4

Related Questions