CODEWITHSUNDEEP
windowsbatch-file
Panade
Panade

Reputation: 289

Windows Batch: getting Path without Shortening

I searched now for several Hours and didnt find any fitting solution for me.

When I try to get the current Path of the Batch File, I use normaly %~dp0. This will leads in Paths like: D:\VM\TUTORI~2\STARTS~1.BAT

However this is not an issue, if only doing File Management, but I want to use the Script to call Vagrant commands. It happens that the Vagrant System doesnt like this shortened Paths. As soon as the Path is short enough or when I call it from the CMD directly, it works just fine.

I'm now searching for a way to get any unshortened Path to my working Directory. But whatever I tried so far didnt work and google only delivers me how people Shorten their Paths. Is there a practical Solution to this Problem?

I want to set a Variable in my Script looking like this: D:\VM\tutorialtest

EDIT:

According to the Accepted Answer the working snippet for me is the Snippet without the "-2" on the 2. For Loop. This will give me the Path no matter where the folder is. 

setlocal EnableDelayedExpansion
set myPath=%~DP0
set myPath=%myPath:*\=%
set fullPath=
pushd \
for %%a in ("%myPath:\=" "%") do (
   set thisDir=%%~a
   for /D %%d in ("!thisDir:~0!*") do (
      set fullPath=!fullPath!\%%d
      cd %%d
   )
)
popd
echo Full path: %~D0%fullPath%

Result:

D:\VM\tutorialtest

Upvotes: 0

Views: 937

Answers (4)

Aacini
Aacini

Reputation: 67216

Try this:

@echo off
setlocal EnableDelayedExpansion

set "myPath=%~DP0"
set "myPath=%myPath:*\=%"
set "fullPath="
pushd \
for %%a in ("%myPath:\=" "%") do (
   set "thisDir=%%~a"
   for /D %%d in ("!thisDir:~0,-2!*") do (
      set "fullPath=!fullPath!\%%d"
      cd "%%d"
   )
)
popd
echo Full path: %~D0%fullPath%

Post the result, please.

EDIT: Bug fixed

The problem is that names that have less than 2 characters are cutted! (my mistake).

I did some testing and it seems that for /D %%d in ("TUTORI~2*") ... also returns the full name of the folder, so thisDir variable is not required. You may modify the for %%a loop this way and get the same result:

for %%a in ("%myPath:\=" "%") do (
   for /D %%d in ("%%~a*") do (
      set fullPath=!fullPath!\%%d
      cd %%d
   )
)

Upvotes: 1

foxidrive
foxidrive

Reputation: 41234

If this behaviour occurs when you open a cmd window, then type echo %comspec% at the cmd prompt and see what it returns: if it has command.com as part of it then it has been altered.

Another possibility is that the shortcut you are using to open a cmd window has command.com in the properties to launch it.

If you are using a shortcut then try to open a cmd prompt from the Win+R hotkey and type cmd and enter. See if this behaviour has changed but also check the first point above once more.

Upvotes: 0

gbabu
gbabu

Reputation: 1108

Edit - Corrected the code which can work with path with or without spaces. 

for /f "delims=" %i in ('dir ^| findstr /i /c:"Directory of"') do set mypath=%i
set mypath=%mypath: Directory of =%

Above codes will work if you type them directly in command console, if you want to use it in batch file use it as below.

for /f "delims=" %%i in ('dir ^| findstr /i /c:"Directory of"') do set mypath=%%i
set mypath=%mypath: Directory of =%

I believe you are in need of getting the current working directory(something like pwd in Unix). 'dir' command usually returns the current path details along with variuos other details. We just pick the line with the directory name (line with the tag "Directory of") and then in the second line we remove the tag "Directory of" (replacing it with none).

Refer the below link for more string manipulation techniques.

http://www.dostips.com/DtTipsStringManipulation.php

Sample output - typed on command console

C:\test\new folder>for /f "delims=" %i in ('dir ^| findstr /i /c:"Directory of"') do set mypath=%i

C:\test\new folder>set mypath= Directory of C:\test\new folder

C:\test\new folder>set mypath=%mypath: Directory of =%

C:\test\new folder>echo.%mypath%

Upvotes: 1

SachaDee
SachaDee

Reputation: 9545

Did you try :

set $path=%cd%
echo %$path%

Upvotes: 0

Related Questions