CODEWITHSUNDEEP
gnuplotmodel-fitting
user3916321
user3916321

Reputation: 81

Gnuplot fit of a nested function

What is the proper way in gnuplot to fit a function f(x) having the next form?

f(x) = A*exp(x - B*f(x))

I tried to fit it as any other function using:

fit f(x) "data.txt" via A,B

and the output is just a sentence saying: "stack overflow"

I don't even know how to look for this topic so any help would be much appreciate it.

How are this kind of functions called? Nested? Recursive? Implicit?

Thanks

Upvotes: 5

Views: 1022

Answers (3)

user3916321
user3916321

Reputation: 81

Thanks for your replies

Discussing with a friend about this problem I found a way around.

First, this kind of functions are call "transcendental functions", that means that the function f(x) is not explicitly solvable, but the variable x could be solved as a function of f(x) and it will have the next form

x = B*f(x) + log(f(x)/A)

Therefore it is possible to define a new function (that is not transcendental)

g(x) = B*x + log(x/A)

From here you can fit the function g(x) to the plot x vs y. Using gnuplot it is possible to do the fitting as

fit g(x) "data.txt" using ($2):($1) via A,B

Hope this will help someone else

Upvotes: 3

Christoph
Christoph

Reputation: 48390

That is a recursive function. You need a condition for the recursion to stop, like a maximum number of iterations:

maxiter = 10
f(x, n) = (n > maxiter ? 0 : A*exp(x - B*f(x, n+1)))

fit f(x, 0) "data.txt" via A,B

Of course you must check, which value should be returned when the recursion is stopped (here I used 0)

Upvotes: 5

Miguel
Miguel

Reputation: 7627

This doen't only fail for fitting, also for plotting. You'll have to write down the explicit form of f(x), otherwise gnuplot will loop it until it reaches its recursion limit. One way to do it would be to use a different name:

f(x) = sin(x) # for example
g(x) = A*exp(x - B*f(x))

And now use g(x) to fit, rather than f(x). If you have never declared f(x), then gnuplot doesn't have an expression to work with. In any case, if you want to recursively define a function, you'll at least need to set a recursion limit. Maybe something like this:

f0(x) = x
f1(x) = A*exp(x - B*f0(x))
f2(x) = A*exp(x - B*f1(x))
f3(x) = A*exp(x - B*f2(x))
...

This can be automatically looped:

limit=10
f0(x) = x
do for [i=1:limit] {
j=i-1
eval "f".i."(x) = A*exp(x - B*f".j."(x))"
}

Using the expression above you set the recursion limit with the limit variable. In any case it shall remain a finite number.

Upvotes: 5

Related Questions