CODEWITHSUNDEEP
haskellquickcheck
pkinsky
pkinsky

Reputation: 1758

Multiple arbitrary calls returning same value

I expect the below code to produce a generator of lists of a of size 1, 2 or 3, with each element generated independently. 

shortlist :: Arbitrary a => Gen [a]
shortlist = oneof $ map promote [[arbitrary],  
                                 [arbitrary, arbitrary], 
                                 [arbitrary, arbitrary, arbitrary]]

REPL:

sample (shortlist :: Gen [Char])
"\255\255\255"
"ii"
"FF"
"\236\236"
"FF"
"'''"
"8"
"HH"
"\160"
"\DEL\DEL\DEL"
"\246\246"

Each list contains 1, 2 or 3 instances of the same char. Why is arbitrary not behaving as expected?

Upvotes: 0

Views: 94

Answers (2)

Carl
Carl

Reputation: 27013

I really had to look for promote. The module description says that the functions provided in that module will reuse random number seeds. Instead of using promote, you should use something like replicateM or sequence.

For example:

shortlist :: Arbitrary a => Gen [a]
shortlist = oneof $ map sequence [[arbitrary],  
                                  [arbitrary, arbitrary], 
                                  [arbitrary, arbitrary, arbitrary]]

or

shortlist :: Arbitrary a => Gen [a]
shortlist = oneof $ [ replicateM n arbitrary | n <- [1..3] ]

will yield something like:

> sample (shortlist :: Gen [Char])
"\SI"
"aP"
"\153\US\STX"
"#k"
"U"
"}\DC1"
"i"
"\186F"
"\148k"
"\RS|\159"
"\192L"

Upvotes: 6

ErikR
ErikR

Reputation: 52039

In QuickCheck-2.7.6. promote has been moved to the Test.QuickCheck.Gen.Unsafe module.

The comments there explain what you are seeing:

Gen is only morally a monad: two generators that are supposed to be equal will give the same probability distribution, but they might be different as functions from random number seeds to values. QuickCheck maintains the illusion that a Gen is a probability distribution and does not allow you to distinguish two generators that have the same distribution.

The functions in this module allow you to break this illusion by reusing the same random number seed twice. This is unsafe because by applying the same seed to two morally equal generators, you can see whether they are really equal or not.

Upvotes: 6

Related Questions