CODEWITHSUNDEEP
perlsubstitutionsubroutineidiomatic-perl
Thomas L Holaday
Thomas L Holaday

Reputation: 13814

Is there a Perl idiom which is the functional equivalent of calling a subroutine from within the substitution operator?

Perl allows ...

$a = "fee";
$result = 1 + f($a) ; # invokes f with the argument $a

but disallows, or rather doesn't do what I want ...

s/((fee)|(fie)|(foe)|(foo))/f($1)/ ; # does not invoke f with the argument $1

The desired-end-result is a way to effect a substitution geared off what the regex matched.

Do I have to write

sub lala {
  my $haha = shift;
  return $haha . $haha;
}
my $a = "the giant says foe" ;
$a =~ m/((fee)|(fie)|(foe)|(foo))/;
my $result = lala($1);
$a =~ s/$1/$result/;
print "$a\n";

Upvotes: 1

Views: 153

Answers (1)

Sinan Ünür
Sinan Ünür

Reputation: 118138

See perldoc perlop. You need to specify the e modifier so that the replacement part is evaluated.

#!/usr/bin/perl

use strict; use warnings;

my $x = "the giant says foe" ;
$x =~ s/(f(?:ee|ie|o[eo]))/lala($1)/e;

print "$x\n";

sub lala {
    my ($haha) = @_;
    return "$haha$haha";
}

Output:

C:\Temp> r
the giant says foefoe

Incidentally, avoid using $a and $b outside of sort blocks as they are special package scoped variables special-cased for strict.

Upvotes: 12

Related Questions