CODEWITHSUNDEEP
perl
Gunnerfan
Gunnerfan

Reputation: 123

print function in Perl

This is a perl code I use for compiling pressure data.

$data_ct--;
mkdir "365Days", 0777 unless -d "365Days";
my $file_no = 1;
my $j = $num_levels;
for ($i = 0; $i < $data_ct; $i++) {
    if ($j == $num_levels) {
        close OUT;
        $j = 0;
        my $file = "365days/wind$file_no";
        $file_no++;
        open OUT, "> $file" or die "Can't open $file: $!";
    }
    {
        $wind_direction = (270-atan2($vwind[$i], $uwind[$i])*(180/pi))%360;
    }
    $wind_speed = sqrt($uwind[$i]*$uwind[$i]+$vwind[$i]*$vwind[$i]);
    printf OUT "%.0f %.0f %.1f\n", $level[$i], $wind_direction, $wind_speed;
    $j++;
}
$file_no--;
print STDERR "Wrote out $file_no wind files.\n";
print STDERR "Done\n";

The problem I am having is when it prints out the numbers, I want it to be in this format

Level  Wind direction  windspeed
 250         320            1.5
 870         56             4.6

Right now when I run the script the columns names do not show up rather just the numbers. Can someone direct me as to how to rectify the script?

Upvotes: 0

Views: 452

Answers (3)

David W.
David W.

Reputation: 107040

Okay, Matlock wasn't on tonight, so this crusty old Perl programmer has plenty of time.

In my previous answer, I said there was an old way of doing forms in Perl, but I didn't remember how it went. Well, I spent some time and got you an example of how it works.

Basically, you sort of need globalish variables. I thought you needed our variables for this to work, but I can get my variables to work if I define them on the same level as my format statements. It's not pretty.

You use GLOBS to define your formats with _TOP appended for your headers. Since I'm printing these on STDOUT, I define STDOUT_TOP for my heading and STDOUT for my data lines.

The format must start at the beginning of a column. The lone . on the end ends the format definition. You notice I write the entire thing with just a single write statement. How does it know to print out the heading? Perl tracks the number of lines printed and automatically writes a Form Feed character and a new heading when Perl thinks it's at the bottom of a page. I am assuming Perl uses 66 line pages as a default.

You can in Perl set your own form names via select. Perl uses $= as the number of lines on a page, and $- on the number of lines left. These variables are global, but are set by the selected format via the select statement. You can use IO::Handle for better variable naming.

#! /usr/bin/env perl

use strict;
use warnings;
use feature qw(say);

my @data = (
    {
        level     => 250,
        direction => 320,
        speed     => 1.5,
    },
    {
        level     => 870,
        direction => 55,
        speed     => 4.5,
    },
);

my $level;
my $direction;
my $speed;
for my $item_ref ( @data ) {

    $level     = $item_ref->{level};
    $direction = $item_ref->{direction};
    $speed     = $item_ref->{speed};
    write;
}

format STDOUT_TOP =

    Level   Wind Direction  Windspeed
    =====   ==============  =========

.

format STDOUT =
    @####   @#############  @#####.##
    $level, $direction,     $speed
.

This prints:

Level   Wind Direction  Windspeed
=====   ==============  =========

  250              320       1.50
  870               55       4.50

Upvotes: 1

David W.
David W.

Reputation: 107040

There are several ways to do this in Perl. First, Perl has built in form ability. It's been a part of Perl since version 3.0 (about 20 years old). However, it is rarely used. In fact, it is so rarely used I am not even going to attempt to write an example with it because I'd have to spend way too much time relearning it. It's there and documented.

You can try to figure it out for yourself. Or, maybe some old timer Perl programmer might wake up from his nap and help out. (All bets are off if it's meatloaf night at the old age home, though).

Perl has evolved greatly in the last few decades, and this old forms bit represents a much older way of writing Perl programs. It just isn't pretty.

Another way this can be done and is more popular is to use the printf function. If you're not familiar with C and printf from there, it can be a bit intimidating to use. It depends upon formatting codes (the things that start with % to specify what you want to print (strings, integers, floating point numbers, etc.), and how you want those values formatted.

Fortunately, printf is so useful, that most programming languages have their own version of printf. Once you learn it, your knowledge is transferable to other places. There's an equivalent sprintf for setting variable with formats.

# Define header and line formats

my $header_fmt = "%-5.5s  %-14.14s  %-9.9s\n";
my $data_fmt   = "%5d  %14d  %9.1f\n";

# Print my table header

printf $header_fmt, "Level", "Wind direction", "windspeed";

my $level = 230;
my $direction = 120;
my $speed = 32.3;

# Print my table data

printf $data_fmt, $level, $direction, $speed;

This prints out:

Level  Wind direction  windspeed
  230             120       32.3

I like defining the format of my printed lines all together, so I can tweak them to get what I want. It's a great way to make sure your data line lines up with your header.

Upvotes: 2

Praveen
Praveen

Reputation: 902

@Gunnerfan : Can you replace the line from your code as shown below

Your line of code: printf OUT "%.0f %.0f %.1f\n",$level[$i], wind_direction, $wind_speed;

Replacement code:

if($i==0) {
  printf OUT "\n\t%s%-20s %-10s%-12s %-20s%s\n", 'Level' , 'Wind direction' , 'windspeed');
  }
printf OUT "\t%s%-20s%s %-10s%s%-12s%s %-20s\n",$level[$i],$wind_direction, $wind_speed;

Upvotes: 0

Related Questions