CLIPS: slots within multislots

Question

I am currently working in CLIPS and I am new to it. I am trying to replicate the following information in a CLIPS deftemplate:

[Person, [Class,Class],[[M 9,11],[F,9,11]]]

It has a person, multiple classes that they can take and the times that they can take the class. I try to replicate this information in the following deftemplate:

(deftemplate person 
   (slot Name)
   (multislot Class)
   (multislot Available))

My problem is I do not understand what I am supposed to do in the available multislot because it has three inputs. Is there a way that I can make slots within a multislot? I have looked online for ways to do this but have not been able to correctly solve this problem.

Answer 1

Here are four different approaches. I would suggest something similar to approach 3 or 4 since these involve simple linkages between facts/instances.

CLIPS> (clear) ; Approach 1
CLIPS> 
(deftemplate person 
   (slot Name)
   (multislot Class)
   (multislot Available))
CLIPS>    
(deffacts people
   (person (Name Frank)
           (Class Biology Calculus)
           (Available M 9 11 F 9 11)))
CLIPS> 
(deffunction #-of-triplets (?mf)
   (div (length$ ?mf) 3))
CLIPS>    
(deffunction nth-triplet (?mf ?n)
   (subseq$ ?mf (+ 1 (* (- ?n 1) 3))(* ?n 3)))
CLIPS>    
(defrule print-availability
    (person (Name ?name)
            (Available $?a))
    =>
    (loop-for-count (?i (#-of-triplets ?a))
       (bind ?triplet (nth-triplet ?a ?i))
       (bind ?d (nth$ 1 ?triplet))
       (bind ?b (nth$ 2 ?triplet))
       (bind ?e (nth$ 3 ?triplet))
       (printout t ?name " " ?d " " ?b " " ?e crlf)))
CLIPS> (reset)
CLIPS> (run)
Frank M 9 11
Frank F 9 11
CLIPS> (clear) ; Approach 2
CLIPS> 
(deftemplate person 
   (slot Name)
   (multislot Class)
   (multislot Available-Weekday)
   (multislot Available-Begin)
   (multislot Available-End))
CLIPS>    
(deffacts people
   (person (Name Frank)
           (Class Biology Calculus)
           (Available-Weekday M F)
           (Available-Begin 9 9)
           (Available-End 11 11)))
CLIPS> 
(defrule print-availability
    (person (Name ?name)
            (Available-Weekday $?f1 ?d $?)
            (Available-Begin $?f2 ?b $?)
            (Available-End $?f3 ?e $?))
    (test (= (length$ ?f1)
             (length$ ?f2)
             (length$ ?f3)))
    =>
    (printout t ?name " " ?d " " ?b " " ?e crlf))
CLIPS> (reset)
CLIPS> (run)
Frank M 9 11
Frank F 9 11
CLIPS> (clear) ; Approach 3
CLIPS> 
(deftemplate person 
   (slot Name)
   (slot ID)
   (multislot Class))
CLIPS>    
(deftemplate availability
   (slot owner-ID)
   (slot Weekday)
   (slot Begin)
   (slot End))
CLIPS>    
(deffacts information
   (person (Name Frank) (ID 1)
           (Class Biology Calculus))
   (availability (owner-ID 1) (Weekday M) (Begin 9) (End 11))
   (availability (owner-ID 1) (Weekday F) (Begin 9) (End 11)))
CLIPS>  
(defrule print-availability
    (person (Name ?name) (ID ?id))
    (availability (owner-ID ?id) (Weekday ?d) (Begin ?b) (End ?e))
    =>
    (printout t ?name " " ?d " " ?b " " ?e crlf))
CLIPS> (reset)
CLIPS> (run)
Frank F 9 11
Frank M 9 11
CLIPS> (clear) ; Approach 4
CLIPS> 
(defclass PERSON
   (is-a USER)
   (slot Name)
   (multislot Class)
   (multislot Available))
CLIPS>    
(defclass AVAILABILITY
   (is-a USER)
   (slot Weekday)
   (slot Begin)
   (slot End))
CLIPS>    
(definstances information
   (of PERSON (Name Frank)
              (Class Biology Calculus)
              (Available (make-instance of AVAILABILITY (Weekday M) (Begin 9) (End 11))
                         (make-instance of AVAILABILITY (Weekday F) (Begin 9) (End 11)))))
CLIPS>                          
(defrule print-availability
    (object (is-a PERSON) (Name ?name) (Available $? ?a $?))
    (object (is-a AVAILABILITY) (name ?a))
    =>
    (printout t ?name " " (send ?a get-Weekday) 
                      " " (send ?a get-Begin) 
                      " " (send ?a get-End) crlf)))
CLIPS> (reset)
CLIPS> (run)
Frank F 9 11
Frank M 9 11
CLIPS>