CODEWITHSUNDEEP
sasaveragemean
Rathod
Rathod

Reputation: 11

How to calculate a mean for the non zero values using proc means or proc summary

I want to have a mean which is based in non zero values for given variables using proc means only. I know we do can calculate using proc sql, but I want to get it done through proc means or proc summary.

In my study I have 8 variables, so how can I calculate mean based on non zero values where in I am using all of those in the var statement as below:

proc means = xyz;
var var1 var2 var3 var4 var5 var6 var7 var8;
run;

If we take one variable at a time in the var statement and use a where condition for non zero variables , it works but can we have something which would work for all the variables of interest mentioned in the var statement?

Your suggestions would be highly appreciated. Thank you !

Upvotes: 1

Views: 4125

Answers (3)

user667489
user667489

Reputation: 9569

Create a view of your input dataset. In the view, define a weight variable for each variable you want to summarise. Set the weight to 0 if the corresponding variable is 0 and 1 otherwise. Then do a weighted summary via proc means / proc summary. E.g.

data xyz_v /view = xyz_v;
    set xyz;
    array weights {*} weight_var1-weight_var8;
    array vars {*} var1-var8;
    do i = 1 to dim(vars);
        weights[i] = (vars[i] ne 0);
    end;
run;

%macro weighted_var(n);
    %do i = 1 to &n;
        var var&i /weight = weight_var&i;
    %end;
%mend weighted_var;

proc means data = xyz_v;
    %weighted_var(8);
run;

This is less elegant than Chris J's solution for this specific problem, but it generalises slightly better to other situations where you want to apply different weightings to different variables in the same summary.

Upvotes: 1

Fernando Aires
Fernando Aires

Reputation: 531

Can't you use a data statement?

data lala;
    set xyz;
    drop qty;
    mean = 0;
    qty = 0;

    if(not missing(var1) and var1 ^= 0) then do;
        mean + var1;
        qty + 1;
    end;

    if(not missing(var2) and var2 ^= 0) then do;
        mean + var2;
        qty + 1;
    end;

    /* ... repeat to all variables ... */

    if(not missing(var8) and var8 ^= 0) then do;
        mean + var8;
        qty + 1;
    end;

    mean = mean/qty;
run;

If you want to keep the mean in the same xyz dataset, just replace lala with xyz.

Upvotes: -1

Chris J
Chris J

Reputation: 7769

One method is to change all of your zero values to missing, and then use PROC MEANS.

data zeromiss /view=zeromiss ;
  set xyz ;
  array n{*} var1-var8 ;
  do i = 1 to dim(n) ;
    if n{i} = 0 then call missing(n{i}) ;
  end ;
  drop i ;
run ;

proc means data=zeromiss ;
  var var1-var8 ;
run ;

Upvotes: 2

Related Questions