CODEWITHSUNDEEP
vbscript
Programmer
Programmer

Reputation: 301

Error: "input past end of file" when using method ReadAll()

I have 3 scripts wherein they all must be run in the right order repeatedly.

  1. 1st script - performs a process on a list of PCs (listed on a textfile input) depending if they are online/offline. It outputs a list of the PCs which were online and another list of the offline ones
  2. 2nd script - gets the PC difference from the original list and the output of the 1st script to know which machines have run the process from the 1st script
  3. 3rd script - using the differences, updates the input list

The script below is the 3rd script. Whenever I run it, it ends with an error "input past end of file". I've tried several modifications and it always ends that way.

My idea for the 3rd script is that the Differences.txt output from the 2nd file are the ones that still need to run the process form the first script, so I simply delete the original input file and rename this one into the new output file. However, I have to also keep track of the ones that were already done with the process so I have to list/append them to another text file.

Option Explicit
Dim objFso
Dim Fso
Dim firstfile,secondfile,file,fileText

Set objFSO = CreateObject("Scripting.FileSystemObject")
If objFSO.FileExists("Machines.ini") Then objFSO.DeleteFile("Machines.ini")

Set Fso = WScript.CreateObject("Scripting.FileSystemObject")
Fso.MoveFile "Differences.txt", "Machines.ini"

firstfile="Notified.txt"
secondfile="Notified-all.txt"

Set fso=CreateObject("Scripting.FileSystemObject")
Set file=fso.OpenTextFile(firstfile)
fileText = fileText & file.ReadAll() & vbCrLf
file.Close

Set file=fso.OpenTextFile(secondfile)
fileText=filetext & file.ReadAll()
file.Close

set file=fso.CreateTextFile(secondfile,true)
file.Write fileText
file.close

Upvotes: 12

Views: 24336

Answers (1)

Ansgar Wiechers
Ansgar Wiechers

Reputation: 200253

You get that error when you call ReadAll on an empty file. Check the AtEndOfStream property and read the content only if it's false:

If Not file.AtEndOfStream Then fileText = fileText & file.ReadAll

Upvotes: 26

Related Questions