CODEWITHSUNDEEP
vbaexcel
h.l.m
h.l.m

Reputation: 13475

Selecting multiple sheets using a range

I have sheet names in cells C2 to C5, which are dynamic. I would like to select them at the same time using VBA.

The only way I have found uses arrays and "hard-coding" the sheet names.

Sub ssheets()
    Worksheets(Array("Sheet2", "Sheet3","Sheet4","Sheet5")).Select
End Sub

I would like something that uses Range("C2:C5") so that I can select the relevant sheets without having to type in "Sheet2", "Sheet3","Sheet4","Sheet5" etc.

Upvotes: 4

Views: 44828

Answers (3)

Vasko
Vasko

Reputation: 39

3 lines of code needed (2, if you want ActiveSheet selected as well):

Sub sSheets()

Set xRange = Range("C2:C5") 'define ur range
  Sheets(xRange.Cells(1).Value).Select    'this is only needed to de-select the ActiveSheet
For Each xCell In xRange: Sheets(xCell.Value).Select False: Next  '[False] is like holding Ctrl and clicking on different tabs

End Sub

Upvotes: 0

ttaaoossuu
ttaaoossuu

Reputation: 7884

Try this:

Sub Macro1()
    Dim sheetArray() As String
    Dim i As Integer
    i = 0
    For Each c In Range("C2:C5").Cells
        ReDim Preserve sheetArray(0 To i)
        sheetArray(i) = c.Value
        i = i + 1
    Next
    Sheets(sheetArray).Select
End Sub

You may also consider adding verification if the sheet with that name exists before adding it to array.

Upvotes: 0

Axel Richter
Axel Richter

Reputation: 61870

The sheet names array has to be of type Variant containing a one dimensional array. The Range("C2:C5") returns a two dimensional array. To use this as sheet names array, you have to transpose it.

Sub ssheets()
    Dim oWS As Worksheet
    Dim aSheetnames As Variant
    Set oWS = Worksheets(1)
    aSheetnames = oWS.Range("C2:C5")
    aSheetnames = Application.WorksheetFunction.Transpose(aSheetnames)
    Worksheets(aSheetnames).Select
End Sub

Upvotes: 3

Related Questions