CODEWITHSUNDEEP
ms-accessms-wordvba
Matt Hall
Matt Hall

Reputation: 2412

Passing MS-Access string >255 characters to MS-Word field

I'm using .FormFields("WordBookmarkName").Result = stringFromAccess method to pass data out of MS-Access to an MS-Word document.

It seems it can only pass up to 255 characters. Is there a way I can pass more to my field in MS-Word?

Edit:

This is a simplified version of the code I was using that works ok up to 255 characters:

Dim startForms As String
Dim appWord As Word.Application
Dim doc As Word.Document

startForms = String(256, "x")

Set appWord = GetObject(, "Word.Application") 'Set appWord object variable to running instance of Word.

If Err.Number <> 0 Then

    Set appWord = New Word.Application 'If Word isn't open, create a new instance of Word.

End If

Set doc = appWord.Documents.Open("C:\myFolder\MyForm.docx", , True)

With doc

    .FormFields("wdStartForms").Result = "" 'Clear anything currently in the form's field
    .FormFields("wdStartForms").Result = startForms

    .Visible = True
    .Activate

End With

Set doc = Nothing
Set appWord = Nothing

JohnnyBones: this is the code I adapted after your answer; using ActiveDocument wasn't working, so I continued to use the doc reference I'd made and it seemed to work ok with 256+ characters after that:

Dim startForms As String
Dim appWord As Word.Application
Dim doc As Word.Document

startForms = String(256, "x")

Set appWord = GetObject(, "Word.Application") 'Set appWord object variable to running instance of Word.

If Err.Number <> 0 Then

    Set appWord = New Word.Application 'If Word isn't open, create a new instance of Word.

End If

Set doc = appWord.Documents.Open("C:\myFolder\MyForm.docx", , True)

With doc

    .FormFields("wdStartForms").Result = "" 'Clear anything currently in the form's field
    .Bookmarks("wdStartForms").Range.Fields(1).Result.Text = startForms
    .Visible = True
    .Activate

End With

Set doc = Nothing
Set appWord = Nothing

Upvotes: 0

Views: 1654

Answers (1)

Johnny Bones
Johnny Bones

Reputation: 8402

If you use:

Dim FmFld As FormField, Str1 As String
Str1 = (a long string > 256 characters)

Set FmFld = ActiveDocument.FormFields(1)
FmFld.Result = Str1

You get an error: “String too long” (a ridiculous “design” feature, given that you can do it manually without problems!).

Same if you use:

ActiveDocument.Formfields("Text1").Result = Str1

You can get round this by using:

ActiveDocument.Unprotect
FmFld.Range.Fields(1).Result.Text = Str1
ActiveDocument.Protect Type:=wdAllowOnlyFormFields, NoReset:=True

Or if you're referring to the formfield by name:

ActiveDocument.Unprotect
ActiveDocument.Bookmarks("Text1").Range.Fields(1).Result.Text = Str1
ActiveDocument.Protect Type:=wdAllowOnlyFormFields, NoReset:=True

You could also try passing multiple strings and concatenating them, chopping each string into chunks less than 255 characters.

Upvotes: 1

Related Questions