CODEWITHSUNDEEP
delphidataset
Mason Wheeler
Mason Wheeler

Reputation: 84540

Delphi: using TClientDataset as an in-memory dataset

According to this page, it's possible to use TClientDataset as an in-memory dataset, completely independent of any actual databases or files. It describes how to setup the dataset's table structure and how to load data into it at runtime. But when I tried to follow its instructions in D2009, step 4 (table.Open) raised an exception. It said that it didn't have a provider specified.

The entire point of the example on that page is to build a dataset that doesn't need a provider. Is the page wrong, is it outdated, or am I missing a step somewhere? And if the page is wrong, what do I need to use instead to create a completely independent in-memory dataset? I've been using TJvMemoryData, but if possible I'd like to reduce the amount of extra dependencies that my dataset adds into my project.

Upvotes: 26

Views: 71853

Answers (11)

avra
avra

Reputation: 3730

This is a corrected working code mentioned by OP in the first post. You get a memory table from a TClientDataset shown in DBGrid.

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, DB, DBClient, Grids, DBGrids, StdCtrls, MidasLib;

type
  TForm1 = class(TForm)
    MemTable: TClientDataSet;
    Button1: TButton;
    Button2: TButton;
    DBGrid1: TDBGrid;
    DataSource1: TDataSource;
    procedure Button1Click(Sender: TObject);
    procedure Button2Click(Sender: TObject);
    procedure FormCreate(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

procedure TForm1.Button1Click(Sender: TObject);
var
  i: word;
begin
  MemTable.DisableControls;
  for i := 1 to 20000 do
  begin
    MemTable.Append;
    MemTable.FieldByName('ID').AsInteger       := i;
    MemTable.FieldByName('Status').AsString    := 'Code'+IntToStr(i);
    MemTable.FieldByName('Created').AsDateTime := Date();
    MemTable.FieldByName('Volume').AsFloat     := Random(10000);
    MemTable.Post;
  end;
  MemTable.EnableControls;
end;

procedure TForm1.Button2Click(Sender: TObject);
begin
  MemTable.IndexFieldNames := 'Volume';
end;

procedure TForm1.FormCreate(Sender: TObject);
begin
  MemTable.FieldDefs.Add('ID',      ftInteger, 0, False);
  MemTable.FieldDefs.Add('Status',  ftString, 10, False);
  MemTable.FieldDefs.Add('Created', ftDate,    0, False);
  MemTable.FieldDefs.Add('Volume',  ftFloat,   0, False);
  MemTable.CreateDataSet;
end;

end.

Upvotes: 0

Tim Sullivan
Tim Sullivan

Reputation: 16888

If you'd like a dependency-free, high quality, and feature rich (not to mention free!) in-memory dataset, I highly recommend kbmMemTable. Does everything TClientDataset does and then some.

Upvotes: 3

Simon
Simon

Reputation:

for some reason this is not working for me. I perform CreateDataset in design time, but it still crashes application. That is still unknown for me. One warning. DO NOT DO THIS:

XXXClientDataSet.Close;
XXXClientDataSet.Open;

because it will report error. Instead of Open, use 

xxxClientDataSet.CreateDataset;

In my application I needed to reset data and load it again, and that again caused error message.

Upvotes: 1

vrad
vrad

Reputation: 836

Don't forget to include MIDAS.DLL in your installation or simply include MidasLib in uses clause. Otherwise using TClientDataSet will raise an error on client's machine. Maybe it's obvious, but I actually forgot this once.

Upvotes: 9

Tom
Tom

Reputation: 1381

You can use table.CreateDataSet

Upvotes: 7

MikeJ
MikeJ

Reputation: 14565

At runtime you can use table.CreateDataset or if this is on a design surface you can right click on the CDS and click create dataset. You need to have specified columns/types for the CDS before you can do this though.

Upvotes: 25

Ludecan
Ludecan

Reputation: 331

For me this was caused by a midas.dll mismatch. I fixed it by adding MidasLib to the main program´s uses clause (thus linking the library statically). More info here: http://codeverge.com/embarcadero.datasnap/tclientdataset-createdataset-failing-wit/1097715 and here: http://edn.embarcadero.com/article/29297

Upvotes: 0

Arioch 'The
Arioch 'The

Reputation: 16045

Graveyard stones below for some libre components

In times of Delphi 5/ Delphi 7 there were initiatives to make any object with published properties (more accurately - array or some collection of those) into a database. On Torry.net those are CollectionDataSet and Object DataSet Years before LINQ and such. But since DB-VCL code is little documented and is spaghetti since 16-bit Delphi 1.0 - those have no development.

There is also callback-based (events-based) Snap Object Dataset, not so outdated. Though it leaves too much IMHO on developers shoulders.

TDBF.sf.net table had in-memory mode, but was early removed. TDBF is dead also.

rxLib/JediVCL has MemoryDataset. Though rxLib target was source-level compatibility since 16-bit Delphi 1 up to Delphi 5. That crippled the code much. In JVCL it had some attention and removing of aging code, but still is half-baked when needed some deeper than trivial usage.

There are also free-for-personal DCU components like SQLMemoryTable, not for recent releases though. I wonder if Firebird Embedded / SQLite could be used to create in-memory table without using system-wide hacks like RAMdrive :-)

Upvotes: 1

Ryan VanIderstine
Ryan VanIderstine

Reputation: 481

My preference is to actually manage the dataset as XML. You can use the designer tools to create the basic structure and then save it to disk. This allows it to be managed outside of the executable, compiled in as a resource, or separately managed in version control.

When doing it in this manner you can use LoadFromFile/Stream and the Save variants. Remember to make proper use of LogChanges and MergeChangeLog depending on your usage.

Upvotes: 0

F.D.Castel
F.D.Castel

Reputation: 2362

The code from this page doesn't work in ANY Delphi version. A call to CreateDataSet already puts the dataset into active state ("opened"). You should use .CreateDataSet OR .Open. Not both.

Use .Open when you want to fetch data from a Provider (via ProviderName property) and .CreateDataSet when you want to populate the Dataset by yourself.

BTW: For an in depth reference about ClientDataSets and its features take a look on excellent Cary Jensen articles on CodeGear Developer Network (read the oldest ones, first)

Upvotes: 6

jrodenhi
jrodenhi

Reputation: 2237

If it helps further, here is a piece of code where I created a ClientDataset that is used as an in-memory table:

procedure TfrmPRMain.ConfigureDataset;
begin
  With cdsMain do begin
    FieldDefs.Add('bDelete', ftBoolean);
    FieldDefs.Add('sSource', ftString, 10);
    FieldDefs.Add('iSection', ftInteger);
    FieldDefs.Add('iOrder', ftInteger);
    FieldDefs.Add('sBranch', ftString, 10);
    FieldDefs.Add('sPulseCode', ftString, 10);
    FieldDefs.Add('sCode', ftString, 10);
    FieldDefs.Add('dtWorkDate', ftDate);
    FieldDefs.Add('iWorkWeek', ftInteger);
    FieldDefs.Add('sName', ftString, 50);
    CreateDataSet;
    LogChanges := False;
    Open;
  end;
end;

You can just substitute your own data information and go. Jack

Upvotes: 23

Related Questions