CODEWITHSUNDEEP
xsltxslt-1.0
Rick
Rick

Reputation: 3

Handling < > in XSLT 1.0

I have a problem, when trying to read a structure having < > in source XML.

Input Structure - 

<?xml version="1.0" encoding="UTF-8"?>
<RecordsData>
  <RecordsData>
    <UID>&lt;RecordsData xmlns=&quot;&quot;&gt;&lt;RecordsData&gt;&lt;UID&gt;200&lt;/UID&gt;&lt;RID&gt;Test-1&lt;/RID&gt;&lt;Date&gt;20142812&lt;/Date&gt;&lt;Status&gt;N&lt;/Status&gt;&lt;/RecordsData&gt;&lt;/RecordsData&gt;</UID>
  </RecordsData>
</RecordsData>

Expected Output Structure (there are two requirements) - One is just conversion of &lt; &gt;into well formed XML tags.

<?xml version="1.0" encoding="UTF-8"?>
<RecordsData>
  <RecordsData>
    <UID><RecordsData xmlns=""><RecordsData><UID>200</UID><RID>Test-1</RID><Date>20142812</Date><Status>N</Status></RecordsData></RecordsData></UID>
  </RecordsData>
</RecordsData>

Second is extraction of whole data inside UID tag with output as only below -

<RecordsData xmlns=""><RecordsData><UID>200</UID><RID>Test-1</RID><Date>20142812</Date><Status>N</Status></RecordsData></RecordsData>

I am able to get second output if I have first one in hand. But struggling to get first output from Input over last few days after searching forum extensively and being very new to XSLT.

If we can directly get second output from input source - it's actually what is expected solution. For above - I just tried to break down problem into steps.

Any of experts can you please help!

Thanks,

Upvotes: 0

Views: 6305

Answers (1)

michael.hor257k
michael.hor257k

Reputation: 116959

Conversion is easy, extraction is not.

To convert the escaped markup to real markup, simply disable the escaping when writing the node to the result tree, for example:

XSLT 1.0

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
<xsl:strip-space elements="*"/>

<!-- identity transform -->
<xsl:template match="@*|node()">
    <xsl:copy>
        <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
</xsl:template>

<xsl:template match="UID">
    <xsl:copy>
        <xsl:value-of select="." disable-output-escaping="yes"/>
    </xsl:copy>
</xsl:template>

</xsl:stylesheet>

Ideally, you would use the resulting XML file to extract any data from the escaped portion. Otherwise you would have to apply string functions for this purpose, since the escaped text is not XML.

However, in your example, you don't want to extract anything particular from the data, just isolate it and convert it to a stand-alone markup document. This can be easily accomplished by:

XSLT 1.0

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>

<xsl:template match="/">
    <xsl:value-of select="RecordsData/RecordsData/UID" disable-output-escaping="yes"/>
</xsl:template>

</xsl:stylesheet>

Upvotes: 1

Related Questions